Mikrotik 脚本问题 - 如何将 ARP 列表中的 ip 和 mac 地址添加到 dhcp - 服务器/租约？？？ （请帮忙）

Question

I was wondering if you can help me with the following: I am using Mikrotik scripting on Winbox64, and I want to basically add all the ip's and their mac addresses to dhcp-server leases from the ARP list

I am using currently a command on Winbox64 Mikrotik terminal: ip dhcp-server lease > add address=xxx.xx.xx.xx mac-address=xx:xx:xx:xx:xx:xx, so it adds manually each address individually, but I want to move all of them automatically, with perhaps a code loop.

Would it be possible ? and if so, how would the code be constructed ? I was thinking foreach loop, but still not sure... Forgive me if it's too obvious I am only a beginner on this, and I spent some time figuring it out

Thank you in advance!

Answer 1

This should be the start of something. Loop throught the arp. if the mac doesn't exist in leases add the lease.

:local leaseexists

:foreach ARPID in=[/ip arp find] do={


:local ipaddr [/ip arp get $ARPID address]
:local macaddr [/ip arp get $ARPID mac-address]
:local iface [/ip arp get $ARPID interface]


:if ( $macaddr~":" ) do={

    :local leaseexists 0;

    :foreach LEASEID in=[/ip dhcp-server lease find where mac-address="$macaddr"] do={
        :set leaseexists 1
    }

    :if ( $leaseexists = 0 &&  $iface = "INSIDE") do={

        :local date [/system clock get date];
        :local time [/system clock get time];

        /ip dhcp-server lease add address=$ipaddr mac-address=$macaddr server=all comment="arp-to-lease {*date:$date*} {*time:$time*}"

        :foreach LEASEID in=[/ip dhcp-server lease find where mac-address="$macaddr"] do={
            /tool fetch url="http://notify.updateserver.net/notify/lease/$LEASEID" keep-result=no
        }
 
    } 

}

}