Power Bi - 两列日期

Question

I would like an help for power bi. I have several projects in rows and 12 months in different columns for budget, plus other 12 months for actual expenses.

I have done unpivot to have the actual expenses and budget in two different columns (instead of 24 --> 2 times 12 months). The problem is that I end up with two different columns with the date, one for the actual sales and one for budget and I am stucked. How to solve this issue? Any better way to do?

Thanks

Answer 1

With adequate data, it is now easier to see what you are dealing with and what you want.

• It appears as if you need to repeat the Project and Manager columns. So select them and then Unpivot other columns
• Then split the Attribute Column into Month and what I called a "ValueType" column (Budget, Actual, Latest)
• Pivot with no aggregation on the ValueType column
• Then some cleanup with sorting and re-arranging the columns.

Explore the Applied steps and also read the comments in the M-Code to better understand the algorithm

let
    Source = Excel.CurrentWorkbook(){[Name="Table5"]}[Content],

//Get list of monthcolumns for setting data type and Count
        monthCols = List.Select(Table.ColumnNames(Source), each
               Text.Contains(_,"Jan",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Feb",Comparer.OrdinalIgnoreCase)
            or Text.Contains(_,"Mar",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Apr",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"May",Comparer.OrdinalIgnoreCase)
            or Text.Contains(_,"Jun",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Jul",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Aug",Comparer.OrdinalIgnoreCase)
            or Text.Contains(_,"Sep",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Oct",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Nov",Comparer.OrdinalIgnoreCase) 
            or Text.Contains(_,"Dec",Comparer.OrdinalIgnoreCase)),

        typer = {{"Project", Int64.Type},{"Manager", Text.Type}} & 
                      List.Transform(monthCols, each {_, Int64.Type}),
        numMonths = List.Count(monthCols)/3,
    #"Changed Type" = Table.TransformColumnTypes(Source,typer),

//Unpivot all except Project and Manager columns
    #"Unpivoted Other Columns" = Table.UnpivotOtherColumns(#"Changed Type", {"Project", "Manager"}, "Attribute", "Value"),

//Split the Attribute (budget date/type) column to separate the Month and the Type
    #"Split Column by Delimiter" = Table.SplitColumn(#"Unpivoted Other Columns", "Attribute", 
        Splitter.SplitTextByEachDelimiter({" "}, QuoteStyle.Csv, false), {"Month", "ValueType"}),
    #"Changed Type1" = Table.TransformColumnTypes(#"Split Column by Delimiter",{{"Month", type text}, {"ValueType", type text}}),

//Add Index and Modulo (number of months) for later sorting
    #"Added Index" = Table.AddIndexColumn(#"Changed Type1", "Index", 0, 1, Int64.Type),
    #"Calculated Modulo" = Table.TransformColumns(#"Added Index", {{"Index", each Number.Mod(_, numMonths), type number}}),

//Pivot on ValueType
    #"Pivoted Column" = Table.Pivot(#"Calculated Modulo", List.Distinct(#"Calculated Modulo"[ValueType]), "ValueType", "Value"),

//Add another Index - Integer/Division for sorting
    #"Added Index1" = Table.AddIndexColumn(#"Pivoted Column", "Index.1", 0, 1, Int64.Type),
    #"Inserted Integer-Division" = Table.AddColumn(#"Added Index1", "Integer-Division", 
        each Number.IntegerDivide([Index.1], numMonths), Int64.Type),
    #"Removed Columns" = Table.RemoveColumns(#"Inserted Integer-Division",{"Index.1"}),

//Sort, reorder and rename
    #"Sorted Rows" = Table.Sort(#"Removed Columns",{{"Integer-Division", Order.Ascending}, {"Index", Order.Ascending}}),
    #"Removed Columns1" = Table.RemoveColumns(#"Sorted Rows",{"Index", "Integer-Division"}),
    #"Reordered Columns" = Table.ReorderColumns(#"Removed Columns1",{"Project", "Month", "Budget", "Actual", "Latest", "Manager"})
in
    #"Reordered Columns"

Original Data

Results