使用 Terraform（或 ARM 模板）为 Web 测试创建 Azure 警报规则？

Question

I'm trying to create an Alert Rule for an Application Insights → Availability → Standard (preview) test. First off, how do you create a standard test? For now, I resorted to creating the resource by using a resource "azurerm_resource_group_template_deployment" … ; see gist.github.com/alexs77/0b2bd07aae7fbf22bd3c145132475e7d for exactly how.

But even if it were a azurerm_application_insights_web_test , how would an Alert Rule (ie. azurerm_monitor_metric_alert - right?) look like? I'm confused about this part:

# …
resource "azurerm_monitor_metric_alert" "example" {
  # …
  criteria {
    metric_name      = "???"
    metric_namespace = "???"
    # …
  }
# …

What are the correct values to use there?

I am aware about this ancient blog post Creating an Application Insights Web Test and Alert Programmatically from 2015 - 6 years ago. It makes you go to the Azure Resource Explorer :

In Resource Explorer, open your subscription and resource group, then providers, Microsoft Insights. There you'll see two folders that will be important to us today: webtests and alertrules .

When I go to "microsoft.insights", the "folder" alertrules isn't there.

Answer 1

I'm trying to create an Alert Rule for an Application Insights → Availability → Standard (preview) test. First off, how do you create a standard test?

As Standard Test is a preview feature, its currently not added in terraform-azurerm-provider . It can be only deployed from ARM templates as of now. Only Classic Test can be deployed from Terraform for now.

---

But even if it were a azurerm_application_insights_web_test, how would an Alert Rule (ie. azurerm_monitor_metric_alert - right?) look like?

You don't have to use criteria / dynamic criteria instead you should use application_insights_web_test_location_availability_criteria . So, metric_name and metric_namespace won't be required. Using that your code for classic web test with alert rule will look something like below:

provider "azurerm" {
  features{}
}
data "azurerm_application_insights" "example" {
  name="ansumantestapp"
  resource_group_name = "ansbalrg"
}

resource "azurerm_application_insights_web_test" "example" {
  name                    = "tf-test-appinsights-webtest"
  location                = data.azurerm_application_insights.example.location
  resource_group_name     = data.azurerm_application_insights.example.resource_group_name
  application_insights_id = data.azurerm_application_insights.example.id
  kind                    = "ping"
  frequency               = 300
  timeout                 = 60
  enabled                 = true
  geo_locations           = ["us-ca-sjc-azr", "us-va-ash-azr"]

  configuration = <<XML
<WebTest Name="WebTest1" Id="ABD48585-0831-40CB-9069-682EA6BB3583" Enabled="True" CssProjectStructure="" CssIteration="" Timeout="0" WorkItemIds="" xmlns="http://microsoft.com/schemas/VisualStudio/TeamTest/2010" Description="" CredentialUserName="" CredentialPassword="" PreAuthenticate="True" Proxy="default" StopOnError="False" RecordedResultFile="" ResultsLocale="">
  <Items>
    <Request Method="GET" Guid="a5f10126-e4cd-570d-961c-cea43999a200" Version="1.1" Url="http://microsoft.com" ThinkTime="0" Timeout="300" ParseDependentRequests="True" FollowRedirects="True" RecordResult="True" Cache="False" ResponseTimeGoal="0" Encoding="utf-8" ExpectedHttpStatusCode="200" ExpectedResponseUrl="" ReportingName="" IgnoreHttpStatusCode="False" />
  </Items>
</WebTest>
XML

}
resource "azurerm_monitor_action_group" "main" {
  name                = "example-actiongroup"
  resource_group_name = data.azurerm_application_insights.example.resource_group_name
  short_name          = "exampleact"
  email_receiver {
    name                    = "sendtoadmin"
    email_address           = "myemailid"
    use_common_alert_schema = true
  }
}

resource "azurerm_monitor_metric_alert" "example" {
  name                = "example-metricalert"
  resource_group_name = data.azurerm_application_insights.example.resource_group_name
  scopes = [azurerm_application_insights_web_test.example.id,data.azurerm_application_insights.example.id]
  description         = "PING test alert"

application_insights_web_test_location_availability_criteria {
  web_test_id = azurerm_application_insights_web_test.example.id
  component_id = data.azurerm_application_insights.example.id
  failed_location_count = 2
}

  action {
    action_group_id = azurerm_monitor_action_group.main.id
  }
}

Output: