松树脚本：RSI 指标为线着色

Question

I use the basic RSI Indicator

Here the code

//@version=5
indicator(title="Relative Strength Index", shorttitle="RSI", format=format.price, precision=2, 
timeframe="", timeframe_gaps=true)
len = input.int(14, minval=1, title="Length")
src = input(close, "Source")
up = ta.rma(math.max(ta.change(src), 0), len)
down = ta.rma(-math.min(ta.change(src), 0), len)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - (100 / (1 + up / down))
plot(rsi, "RSI", color=#7E57C2)
band1 = hline(70, "Upper Band", color=#787B86)
bandm = hline(50, "Middle Band", color=color.new(#787B86, 50))
band0 = hline(30, "Lower Band", color=#787B86)
fill(band1, band0, color=color.rgb(126, 87, 194, 90), title="Background")

I need to have the line in green when it's up 50% and in red when it's down 50% I have no find solution so if you can help me: it will be cool.

Thanks by advance for your help.

Have a good day

Answer 1

Create a color variable for the color and use ternary operator to set its value.

color rsi_color = rsi >= 50 ? color.green : color.red
plot(rsi, "RSI", color=rsi_color)

Your full code:

//@version=5
indicator(title="Relative Strength Index", shorttitle="RSI", format=format.price, precision=2, timeframe="", timeframe_gaps=true)
len = input.int(14, minval=1, title="Length")
src = input(close, "Source")
up = ta.rma(math.max(ta.change(src), 0), len)
down = ta.rma(-math.min(ta.change(src), 0), len)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - (100 / (1 + up / down))
color rsi_color = rsi >= 50 ? color.green : color.red
plot(rsi, "RSI", color=rsi_color)
band1 = hline(70, "Upper Band", color=#787B86)
bandm = hline(50, "Middle Band", color=color.new(#787B86, 50))
band0 = hline(30, "Lower Band", color=#787B86)
fill(band1, band0, color=color.rgb(126, 87, 194, 90), title="Background")