从 Excel 到 SQL 服务器的 ADO 连接执行但没有返回记录

Question

I have a spreadsheet from which I want to pass SQL script to my SQL server Database, both to retrieve records and run stored procedures.

Here's my code:

Sub ApendPickListData()
Dim SqlConn As New ADODB.Connection
Dim listID As Integer
Dim lists As New ADODB.Recordset
Dim SQLstr As String

SqlConn.ConnectionString = "Provider = 'SQLOLEDB';Server=MyServer\SQLEXPRESS;Database=MyDatabase;Uid=Username;PWD=Password;"
SqlConn.Open

 

 'The following execution of a stored procedure works
    SqlConn.Execute "Exec spListsInsertNew @Type = 'Picking', @Date ='" & Date & "'"
    
SQLstr = "SELECT ItemList.ItemNumber from ItemList"
    'This method doesn't work
    
With lists
    .ActiveConnection = SqlConn
    .Source = SQLstr
    .Open
    Debug.Print .RecordCount
    'prints -1 in the immediate window - no records
End With

'Neither does this method
Set lists = SqlConn.Execute(SQLstr)
Debug.Print lists.RecordCount
'prints -1 in the immediate window - no records    

SqlConn.Close

End Sub

I feel like I'm missing something obvious. I've searched this site and others, found examples where this code should work. I've tested the select statement in SSMS and it works as expected.

Any help would be appreciated!

Answer 1

The code that worked was from Mark Balhoff's comment. Here it is:

Sub ApendPickListData()
Dim SqlConn As New ADODB.Connection
Dim listID As Integer
Dim lists As New ADODB.Recordset
Dim SQLstr As String

SqlConn.ConnectionString = "Provider = 'SQLOLEDB';Server=Myserver\SQLEXPRESS;Database=MyDB;Uid=Username;PWD=Password;"
SqlConn.Open


SQLstr = "select dbo.ItemList.ItemNumber from dbo.ItemList"

With lists
.ActiveConnection = SqlConn
.Source = SQLstr
.CursorLocation = adUseClient 'This was the key!
.Open
Debug.Print .RecordCount

End With

SqlConn.close
End Sub