使用列名而不是数字在 VLOOKUP function 中使用 VBA 返回一个值

Question

I've managed to write a Vlookup function that works perfectly across multiple sheets using VBA.

However, I have to deal with new workbooks weekly so I'm having to slightly alter my code to ensure the Vlookup in my macro pulls data from the correct columns as these can change.

My code is:

Set my_sheet1 = ThisWorkbook.Worksheets("Sheet1") 
Set my_sheet2 = ThisWorkbook.Worksheets("Sheet2") 

last_row = my_sheet1.Range("A" & Rows.Count).End(xlUp).Row 
last_row1 = my_sheet2.Range("A" & Rows.Count).End(xlUp).Row

Set dataRange = my_sheet2.Range("A2:BA" & last_row1) '//range for data in second worksheet that Vlookup will use to locate third column

On Error Resume Next

  For x = 2 To last_row1

  my_sheet1.Range("D" & x).Value = Application.WorksheetFunction.VLookup(my_sheet1.Range("A" & x).Value, dataRange, 3, 0) 

  Next x

So this VLOOKUP pulls data from Column 3 ("Worker_Name") in Sheet2 into Column D on Sheet1.

Is it possible to use "Worker_Name" instead of 3 in my VLOOKUP? Or do I have to use another function such as MATCH?

Answer 1

You can use Match()

Sub Tester()
    
    Dim my_sheet1 As Worksheet, my_sheet2 As Worksheet
    Dim last_row1 As Long, last_row2 As Long, x As Long
    Dim DataRange As Range, colHeader As String, m, res
    
    Set my_sheet1 = ThisWorkbook.Worksheets("Sheet1")
    Set my_sheet2 = ThisWorkbook.Worksheets("Sheet2")
    
    last_row1 = my_sheet1.Range("A" & Rows.Count).End(xlUp).Row
    last_row2 = my_sheet2.Range("A" & Rows.Count).End(xlUp).Row
    
    Set DataRange = my_sheet2.Range("A2:BA" & last_row2)
    
    colHeader = "Worker_Name"  'column to return results from
    
    'find the column position
    m = Application.Match(colHeader, DataRange.Rows(1), 0)
    
    If Not IsError(m) Then      'got a match?
        For x = 2 To last_row1
            'use the found column
            res = Application.VLookup(my_sheet1.Range("A" & x).Value, DataRange, m, False)
            my_sheet1.Range("D" & x).Value = IIf(IsError(res), "", res) 'check for no match
        Next x
    Else
        MsgBox "Column header '" & colHeader & "' not found", vbExclamation
    End If
End Sub