Yocto - 镜像名称中的 git 修订

Question

By default Yocto adds build timestamp to the output image file name, but I would like to replace it by the revision of my integration Git repository (which references all my layers and configuration files). To achieve this, I put the following code to my image recipe:

def get_image_version(d):
    import subprocess
    import os.path

    try:
        parentRepo = os.path.dirname(d.getVar("COREBASE", True))
        return subprocess.check_output(["git", "describe", "--tags", "--long", "--dirty"], cwd = parentRepo, stderr = subprocess.DEVNULL).strip().decode('UTF-8')
    except:
        return d.getVar("MACHINE", True) + "-" + d.getVar("DATETIME", True)


IMAGE_VERSION = "${@get_image_version(d)}"
IMAGE_NAME = "${IMAGE_BASENAME}-${IMAGE_VERSION}"
IMAGE_NAME[vardepsexclude] = "IMAGE_VERSION"

This code works properly until I change Git revision (eg by adding a new commit). Then I receive the following error:

ERROR: When reparsing /home/ubuntu/yocto/poky/../mylayer/recipes-custom/images/core-image-minimal.bb.do_image_tar, the basehash value changed from 63e1e69797d2813a4c36297517478a28 to 9788d4bf2950a23d0f758e4508b0a894. The metadata is not deterministic and this needs to be fixed.

I understand this happens because the image recipe has already been parsed with older Git revision, but why constant changes of the build timestamp do not cause the same error? How can I fix my code to overcome this problem?

Answer 1

The timestamp does not have this effect since its added to vardepsexclude: https://docs.yoctoproject.org/bitbake/bitbake-user-manual/bitbake-user-manual-metadata.html#variable-flags

[vardepsexclude]: Specifies a space-separated list of variables that should be excluded from a variable's dependencies for the purposes of calculating its signature.

You may need to add this in a couple of places, eg: https://git.yoctoproject.org/poky/tree/meta/classes/image-artifact-names.bbclass#n7

IMAGE_VERSION_SUFFIX ?= "-${DATETIME}"
IMAGE_VERSION_SUFFIX[vardepsexclude] += "DATETIME SOURCE_DATE_EPOCH"
IMAGE_NAME ?= "${IMAGE_BASENAME}-${MACHINE}${IMAGE_VERSION_SUFFIX}"

Answer 2

After some research it turned out the problem was in this line

IMAGE_VERSION = "${@get_image_version(d)}"

because the function get_image_version() was called during parsing. I took inspiration from the source file in aehs29's post and moved the code to the anonymous Python function which is called after parsing.

I also had to add vardepsexclude attribute to the IMAGE_NAME variable. I tried to add vardepvalue flag to IMAGE_VERSION variable as well and in this particular case it did the same job as vardepsexclude . Mentioned Bitbake class uses both flags, but I think in my case using only one of them is enough.

The final code is below:

IMAGE_VERSION ?= "${MACHINE}-${DATETIME}"

IMAGE_NAME = "${IMAGE_BASENAME}-${IMAGE_VERSION}"
IMAGE_NAME[vardepsexclude] += "IMAGE_VERSION"

python () {
    import subprocess
    import os.path

    try:
        parentRepo = os.path.dirname(d.getVar("COREBASE", True))
        version = subprocess.check_output(["git", "describe", "--tags", "--long", "--dirty"], cwd = parentRepo, stderr = subprocess.DEVNULL).strip().decode('UTF-8')
        d.setVar("IMAGE_VERSION", version)

    except:
        bb.warning("Could not get Git revision, image will have default name.")
}

EDIT: After some research I realized it's better to define a global variable in layer.conf file of the layer containing the recipes referencing the variable. The variable is set by a python script and is immediately expanded to prevent deterministic build warning:

layer.conf:

require conf/image-version.py.inc
IMAGE_VERSION := "${@get_image_version(d)}"

image-version.py.inc:

def get_image_version(d):
    import subprocess
    import os.path

    try:
        parentRepo = os.path.dirname(d.getVar("COREBASE", True))
        return subprocess.check_output(["git", "describe", "--tags", "--long", "--dirty"], cwd = parentRepo, stderr = subprocess.DEVNULL).strip().decode('UTF-8')
    except:
        bb.warn("Could not determine image version. Default naming schema will be used.")
        return d.getVar("MACHINE", True) + "-" + d.getVar("DATETIME", True)

I think this is cleaner approach which fits BitBake build system better.