在 Microsoft Access 中使用 SQL 将多值字段拆分为不同的行

Question

I've got a simple table in Microsoft Access that looks like this:

Primary Key	Applications List
123	<Value>|<Value>,<Value>|<Value>
456	<Value>|<Value>,<Value>|<Value>

I need to break out the list of applications into separate rows using the “,” as a delimiter so the end result is a table that looks like this:

Primary Key	Applications List
123	<Value>|<Value>
123	<Value>|<Value>
456	<Value>|<Value>
456	<Value>|<Value>

I've tried using the Split function but can't figure out how to split on the “,” and output the results to a different row like the second table above. I would greatly appreciate your help figuring this one out. Thanks so much!

Answer 1

If you can put a limit on the length of Application List you can build a number table

CREATE TABLE NumTable (ID integer)

up-front with as many rows as there are characters in the longest Application List . Assuming that the longest [Application List] is 1000 characters long, ID=1, ID=2, ..., ID=1000), and then use something like this:

select T.[Primary Key], 
       mid(T.AL,NT.ID+1
           , iif(instr(NT.ID+1,t.AL,',')>0
           ,     instr(NT.ID+1,t.AL,',')-1-nt.ID,1000)) as 
from (select [Primary Key], ',' & [Application List] as AL from tblYourTable) as T
     inner join
     NumTable as NT
     on mid(t.AL,NT.ID,1)=','

You can build the number table in EXCEL and paste it; or write a little VBA routine, or even create it dynamically (*).

I can't imagine it performing very well if the volume is high.

Let us know how you proceed!

(*) Generate numbers 1 to 1000000 in MS Access using SQL

Answer 2

If you setup a Table1 and a Table2 with the same field names, you can run this function to do it for you - it basically loops through Table1 records, splits the Applications List into multiple fields and then inserts new records for each field.

Public Sub SplitDataIntoNewTable()

    Const DATA_SEPARATOR    As String = ","
    Dim qdf                 As DAO.QueryDef
    Dim rsOld               As DAO.Recordset
    Dim rsNew               As DAO.Recordset
    
    Dim i                   As Integer
    Dim lngNumAdded         As Long
    
    Dim lngKey              As Long
    Dim strList             As String
    Dim strNewList          As String
    
    Dim varLists            As Variant
        
    Set rsOld = CurrentDb.OpenRecordset("Table1", dbOpenDynaset, dbReadOnly)
    Set rsNew = CurrentDb.OpenRecordset("Table2", dbOpenDynaset)
    
    With rsOld
        While Not .EOF
            lngKey = ![Primary Key]
            strList = ![Applications List]
            varLists = Split(strList, DATA_SEPARATOR)
            With rsNew
                For i = LBound(varLists) To UBound(varLists)
                    ' Add new record for every list split out of old data
                    .AddNew
                    ' Note that this CANNOT actually be defined as a PRIMARY KEY - it will have duplicates
                    ![Primary Key] = lngKey
                    ![Applications List] = varLists(i)
                    lngNumAdded = lngNumAdded + 1
                    .Update
                Next i
            End With
            .MoveNext
        Wend
        
        rsNew.Close
        .Close
    End With
    
    MsgBox "Added " & lngNumAdded & " New Records"
    
    Set rsOld = Nothing
    Set rsNew = Nothing
End Sub

For example I had Table1 look like this:

And resulting Table2 ended up like this