更改 Access 报告中选定记录的颜色

Question

My Access REPORT has a text box with the Record ID that looks like a button with an on click event to go to a form for that specific record. This works great, but when I return to the report I cannot see which record was clicked. I want to temporarily change ONLY the record that was clicked until another record is selected.

The reason I want this on a report and not a form is because I want the user to have a quick way to proof read in the format needed to print, and make a change or check a detail if necessary, then update the report AFTER all proof reading and updates are completed and before final print. But with many records on the screen it is easy to lose track of which record you were checking when returning from the form.

I tried:

Private Sub btn_txt_GoToTransaction_Click()
  Dim vColor
  vColor = RGB(51, 204, 51) 'green
  Me.btn_txt_GoToTransaction.BackColor = vColor
  DoCmd.OpenForm "Account_frm", acNormal, , "[TransactionID]=" & Me.TransactionID
End Sub

But this does not work because every button turns color not just the selected record.

Any suggestions? Thanks.

Answer 1

This is a great question because there are many benefits to highlighting a row or item in an Access Report. But first, lets discuss the quick answer:

QUICK ANSWER:
In order to just highlight one row or one piece of data in a report, we need to use the "FormatConditions" property. This is the same as Conditional Formating from the MS Access design interface but we are going to change it programmatically on the fly. You can't do this with a button or label - it needs to be a text box with unique data, such as your TransactionID.

STEP 1) I recommend that you add a text box to your report that stretches from the left to the right, set the Back Color and Fore Color to White, set the Control Source to TransactionID, and set the Name to TransactionID. Then right click on this text box and select Position > Send To Back. This works best if the other text boxes and labels on the report have a transparent background.

STEP 2) Add this code:

Private Sub HightlightRow(intRowID As Integer)
    With Me.TransactionID.FormatConditions
        .Delete
        With .Add(acFieldValue, acEqual, intRowID)
            .BackColor = vbGreen
            .ForeColor = vbGreen
        End With
    End With
End Sub

STEP 3) Also change your button code to call this subroutine like this:

Private Sub btn_txt_GoToTransaction_Click()
  HightlightRow Me.TransactionID.Value
  DoCmd.OpenForm "Account_frm", acNormal, , "[TransactionID]=" & Me.TransactionID
End Sub

---

OK, that was the quick answer, but keep reading if you would like more information.

I like to set it up so if the user clicks anywhere in the row, it will pop up with a modal with more detail regarding that row. Also, the user can't make any changes to the data in the Report View, so I use the pop up modal to allow changes. To accomplish this, I do a couple more things:

First , we need to add the code to the OnClick event for every control in that row. Ofcourse, each OnClick event will simply can that subroutine HightlightRow Me.TransactionID.Value

Second , if the user clicks on a Text Box, the Text Box gets the focus and hides the highlight. Therefore, I like to set the focus to something else. In your case, you could set the focus to the button by adding this line to the end of the HighlightRow subroutine: btn_txt_GoToTransaction.SetFocus
In my case, I am not using a button, so I set up a tiny Text Box with = " " (just an equal sign a space in quotation marks) as the Control Source. Then I position this tiny Text Box to the far right. And in the HighlightRow subroutine, I set the focus to this textbox.

---

You may also want a button or method of removing the highlight. To do that simply have the code run this line:

Me.TransactionID.FormatConditions.Delete