Yocto/ Bitbake - 将构建版本（例如 PE、PR 和 PV）合并到 C++ 编译中

Question

I've done a bit of searching but can't find an answer to this issue.

I have a C++ GUI application that is built using Autotools in a Yocto/ Poky image. The PR service has been enabled & for issue tracking I'd like to incorporate the build version of the C++ application into the GUI (so the user can see it's v 0.9.1002 or similar on the GUI).

Is there a way of accomplishing this with a recipe or so I need to amend the Autotools files to build in the build version somehow?

Thanks for looking,

Edit: Thanks for the responses.

The project I put together (based on the the EGT framework) is fairly big & pulled from my repo in github with Yocto/ Bitbake. PV & PE I'll increment as necessary & the PR generation is supplied by Bitbake. A MRE is something like:

#include <egt/ui>

extern char __build_ver // Ideally supplied by Bitbake/ Autotools

int main(int argc, char** argv)
{
    egt::Application app(argc, argv);

    egt::TopWindow window;
    egt::Label label(window, __build_ver);
    egt::center(label);
    window.show();

    return app.run();
}

And the configure.ac is similar to:

AC_PREREQ([2.69])
AC_INIT([egt-demo],[1.3])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_SRCDIR([Makefile.am])
AC_CONFIG_MACRO_DIR([m4])
AC_USE_SYSTEM_EXTENSIONS
AC_CANONICAL_TARGET
PKG_PROG_PKG_CONFIG

AM_INIT_AUTOMAKE([1.10 foreign subdir-objects])

# Enable quiet compiles on automake 1.11.
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

# Initialize libtool
LT_PREREQ([2.2])
LT_INIT([win32-dll])

AC_LANG(C++)
AC_PROG_CXX
AX_CXX_COMPILE_STDCXX([14], [noext])
AC_PROG_CC
AC_PROG_CPP
AC_CHECK_HEADER_STDBOOL
AC_C_INLINE
AC_TYPE_UINT32_T

AX_PTHREAD([LIBS="$PTHREAD_LIBS $LIBS"
            CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
            CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"],
            AC_MSG_ERROR(Can not find pthreads.  This is required.))

AC_DEFUN([EGT_CC_TRY_FLAG], [
  AC_MSG_CHECKING([whether $CC supports $1])
  egt_save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS $1 -Werror"
  AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [egt_cc_flag=yes], [egt_cc_flag=no])
  CFLAGS="$egt_save_CFLAGS"
  if test "x$egt_cc_flag" = "xyes"; then
    ifelse([$2], , :, [$2])
  else
    ifelse([$3], , :, [$3])
  fi
  AC_MSG_RESULT([$egt_cc_flag])
])

MAYBE_WARN="-Wall -Wextra \
-pedantic \
-Wfloat-equal \
-Wsign-compare \
-Wpointer-arith \
-Wwrite-strings \
-Wmissing-declarations \
-Wpacked \
-Wstrict-aliasing=2 -Winit-self \
-Wno-attributes -Wno-long-long \
-Wno-missing-field-initializers \
-Wno-unused-parameter \
-Wno-psabi" # no warnings about gcc abi changes

# invalidate cached value if MAYBE_WARN has changed
if test "x$egt_cv_warn_maybe" != "x$MAYBE_WARN"; then
    unset egt_cv_warn_cflags
fi
AC_CACHE_CHECK([for supported warning flags], egt_cv_warn_cflags, [
    echo
    WARN_CFLAGS=""
    # Some warning options are not supported by all versions of
    # gcc, so test all desired options against the current
    # compiler.
    #
    # Note that there are some order dependencies
    # here. Specifically, an option that disables a warning will
    # have no net effect if a later option then enables that
    # warnings, (perhaps implicitly). So we put some grouped
    # options (-Wall and -Wextra) up front and the -Wno options
    # last.
    for W in $MAYBE_WARN; do
        EGT_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
    done
    egt_cv_warn_cflags=$WARN_CFLAGS
    egt_cv_warn_maybe=$MAYBE_WARN
    AC_MSG_CHECKING([which warning flags were supported])])
WARN_CFLAGS="$egt_cv_warn_cflags"
AC_SUBST(WARN_CFLAGS)

AC_DEFUN([LIBINTL_SRC], [
AC_LANG_PROGRAM([[
#include <libintl.h>
]],[[
char *msg = gettext("test");
]])])

AC_MSG_CHECKING([if libc contains libintl])
AC_LINK_IFELSE([LIBINTL_SRC],
    [AC_MSG_RESULT([yes])
    LIBC_CONTAINS_LIBINTL=Yes],
    [AC_MSG_RESULT([no])
    LIBC_CONTAINS_LIBINTL=])
AC_SUBST([LIBC_CONTAINS_LIBINTL])

AC_CHECK_HEADER([libintl.h],
[NO_GETTEXT=],
[NO_GETTEXT=Yes])
AC_SUBST([NO_GETTEXT])

if test -z "$NO_GETTEXT"; then
    test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
fi

PKG_CHECK_MODULES(LIBEGT, [libegt >= 1.3], [], [
   AC_MSG_ERROR(libegt not found.  This is required.)
])

AC_ARG_WITH([sensors],
    AS_HELP_STRING([--without-sensors], [Ignore presence of sensors and disable it]))
AS_IF([test "x$with_sensors" != "xno"],[
   AC_CHECK_HEADER([sensors/sensors.h], [have_sensors=yes], [have_sensors=no])
   if test "x${have_sensors}" = xyes; then
      CXXFLAGS="-DLUA_USE_READLINE ${CXXFLAGS}"
      LDFLAGS="-lsensors ${LDFLAGS}"
      AC_DEFINE(HAVE_SENSORS, 1, [Have sensors support])
   fi
])
AM_CONDITIONAL([HAVE_SENSORS], [test "x${have_sensors}" = xyes])

AC_ARG_ENABLE([lto],
  [AS_HELP_STRING([--enable-lto], [enable gcc's LTO [default=no]])],
  [enable_lto=$enableval], [enable_lto=no])
if test "x$enable_lto" = "xyes" ; then
  AC_MSG_NOTICE([enabling LTO])
  CFLAGS="$CFLAGS -flto"
  CXXFLAGS="$CXXFLAGS -flto"
fi

AC_CONFIG_FILES([Makefile external/Makefile])
AC_OUTPUT

My Bitbake recipe is:

DESCRIPTION = "XXX Application"
LICENSE = "CLOSED"

PACKAGES = "\
    ${PN} \
    ${PN}-dev \
    ${PN}-dbg \
"


# PR service enabled in local.conf
SRC_URI = "git://git@github.com/xxxxx/xxxxxxxxxxx.git;protocol=ssh;branch=main"
SRCREV="${AUTOREV}"
PV = "1.0+git${SRCPV}"

S = "${WORKDIR}/git"

# out-of-tree building doesn't appear to work for this package.
B = "${S}"

inherit pkgconfig autotools gettext

do_configure_prepend() {
    ( cd ${S};
    ${S}/autogen.sh; cd -)
}


FILES_${PN} += " \
    ${datadir}/xxxxxx/* \
"

python __anonymous () {
    endianness = d.getVar('SITEINFO_ENDIANNESS')
    if endianness == 'be':
        raise bb.parse.SkipRecipe('Requires little-endian target.')
}

Answer 1

I am still not sure I completely understand your problem and its environment (I am completely unfamiliar with bitbake and yocto), but the following will show the package version number as an egt::Label , and even allow the packaging scripts calling configure and make to add more version information. HTH.

#include "config.h"

#include <egt/ui>

char build_version_string[] =
    PACKAGE_VERSION
#ifdef ADDITIONAL_VERSION_STR
    " (" ADDITIONAL_VERSION_STR ")"
#endif
    ;

int main(int argc, char** argv)
{
    egt::Application app(argc, argv);

    egt::TopWindow window;
    egt::Label label(window, build_version_string);

This should make the label show the "1.3" version string from the second argument to AC_INIT() .

And if you want to add additional version information, you can define the ADDITIONAL_VERSION_STR macro when your yocto/bitbake/whatever script/recipe/whatever build the package:

PR=1002
more_version_info="yocto foobar $PR"
tar xf egt-demo-1.3.tar.gz
cd egt-demo-1.3
./configure CPPFLAGS="-DADDITIONAL_VERSION_STR=\"${more_version_info}\"" --prefix=...
make
make install

This should make the label show "1.3 (yocto foobar 1002)" .

Some remarks, in more or less decreasing order of actually being related to the question:

• grep PACKAGE_ config.h might reveal more interesting information, especially if you read https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Initializing-configure.html and use more than two arguments to AC_INIT .

• It can be useful to put the char build_version_string[] into its separate compilation unit (C or C++) like build-version.c with a corresponding build-version.h , as this can help avoid potentially expensive rebuilds of a potentially large main.cc file due to changes in config.h .

• This avoids macros or symbols starting with _ or __ , as those usually are reserved by C or C++ language standards.

• If configure calls macros not shipped by Autoconf or Automake, I recommend to explicitly m4_pattern_forbid them. This will make autoreconf runs fail early, if any of the necessary m4 macros cannot be found and therefore unexpanded macro invocations like PKG_* or LT_* or AX_* might appear in the generated configure script:

   m4_pattern_forbid([PKG_PROG_PKG_CONFIG]) PKG_PROG_PKG_CONFIG

• The Autoconf release 2.69 you require was released 2012-04-25. The Automake release 1.10 you require was released 2006-10-15. The Automake release 1.11 which introduced the silent-rules option to AM_INIT_AUTOMAKE and the AM_SILENT_RULES macro was released 2009-05-17. So you can reasonably presume that any system with autoconf 2.69 will probably have an automake version which is less than three years older, and remove the conditional around AM_SILENT_RULES and just use

  AM_INIT_AUTOMAKE([ 1.11 foreign subdir-objects ]) AM_SILENT_RULES([yes])

  or

  AM_INIT_AUTOMAKE([ 1.11 foreign silent-rules subdir-objects ])

  instead of

  # Enable quiet compiles on automake 1.11. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

  but this is starting to get off-topic.

Answer 2

To help others I'll post this as a suggested answer, credit goes to ndim really, this is just putting their answer into a Bitbake format. My recipe layout is as follows:

└── helloworld
    ├── files
    │   ├── config.h
    │   └── helloworld.c
    └── helloworld_0.1.bb

helloworld.c is based on the Yocto manual example:

#include <stdio.h>
#include "config.h"

int main() {
   printf("Hello, World!\n");
   printf("PE = %s, PV = %s, PR = $s\n", PE, PV, PR);
   printf("YOCTO_BUILD_VERSION = %s\n", YOCTO_BUILD_VERSION);
   return 0;
}

config.h:

#define PE "1"
#define PV "2"
#define PR "3"

& finally helloworld_0.1.bb:

SUMMARY = "Simple helloworld application"
SECTION = "examples"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"

SRC_URI = "file://helloworld.c  \
           file://config.h      \
           "

S = "${WORKDIR}"

TARGET_CC_ARCH += "${LDFLAGS}"

do_configure() {
    # Make clean required?
    echo "#define YOCTO_BUILD_VERSION \"${PR}\"" >> config.h
}

do_compile() {
    ${CC} helloworld.c -o helloworld
}

do_install() {
    install -d ${D}${bindir}
    install -m 0755 helloworld ${D}${bindir}
}

This compiles without issue but I need to try it on a board.

For an autotools build I think the do_compile may need to be replaced with EXTRA_OECONF but I need to try it out.

If anyone comes up with a better way I'd be grateful to see it.

Thanks for all the help!

Answer 3

A possible further refinement on this answer is below using sed.

#include <stdio.h>
#include "config.h"

int main() {
   printf("Hello, World!\n");
   printf("Yocto build version = YOCTO_BUILD_VER");
   return 0;
}

& in the Yocto recipe:

PV = "0.9.1"

do_configure_prepend() {

# Amend src/buildVersion.h with Yocto Image Version for display in GUI
( cd ${S}/src;
sed -i 's/YOCTO_BUILD_VER/${PV}/' ${S}/helloworld.c; cd -)

}

I haven't tested this (but something similar does work) but I think the idea is fairly straightforward.