如何在谷歌表格中使用 sumif 和 arrayformula

Question

From google forms, we will get inputs of vehicle nos. over a period of time, and some of these vehicle may be the same. Over this period, we may have noted the traffic offence made by this vehicle. Is there a code/function we can write to sum of the offences the said vehicle had violated?

Col A:Timestamp Col B:Vehicle No. (Data obtained from google form) Col C:Entry Count (obtained via VLookup/Query ~ similar to countif based on Col B) Col D:Violation Count (1 if yes, empty cell means no) Col E:Total Violation Count ~ hoping to sum the total based on Col B.

As such, with each new google form submission, the google sheet will check what is the total number of offences the said vehicle had accumulated and automate in Col E.

Thank you for your guidance.

Answer 1

If you need to have the same total amount of violations on every row for the vehicle then it would be:

=ARRAYFORMULA(
  IF(
    ROW(D:D) = 1,
      "Total Violation Count",
      IFNA(VLOOKUP(
        D:D,
        QUERY(
          D:E,
          "SELECT D, COUNT(D)
           WHERE E IS NOT NULL
           GROUP BY D"
        ),
        2,
      ))
  )
)

If you need a running sum for the number of violations:

=ARRAYFORMULA(
  IFS(
    ROW(D:D) = 1,
      "Total Violation Count",
    A:A = "",,
    True,
      IFNA(VLOOKUP(
        MATCH(D:D, UNIQUE(FILTER(D2:D, D2:D <> "")),) * 10^INT(LOG10(ROWS(D2:D)) + 1) + ROW(D:D),
        SORT(
          {
            SEQUENCE(COUNTUNIQUE(D2:D)) * 10^INT(LOG10(ROWS(D2:D)) + 1),
            IF(SEQUENCE(COUNTUNIQUE(D2:D)), 0);
            FILTER(MATCH(D2:D, UNIQUE(FILTER(D2:D, D2:D <> "")),) * 10^INT(LOG10(ROWS(D2:D)) + 1) + ROW(D2:D), E2:E <> ""),
            MMULT(
                (FILTER(D2:D, E2:E <> "") = TRANSPOSE(FILTER(D2:D, E2:E <> "")))
              * (SEQUENCE(COUNTA(E2:E)) >= SEQUENCE(1, COUNTA(E2:E))),
              SEQUENCE(COUNTA(E2:E), 1, 1,)
            )
          }
        ),
        2
      ))
  )
)

Be aware that the 2nd solution has a restriction: n^2 < 10 000 000, where n is the number of records with violations. That is Google Sheets restriction on the total number of cells which is also applied to intermediary calculations.

Column F:F is not used.