从excel中的单元格中获取文本并添加到word中的书签

Question

I'm trying to do something that seems so simple: Take the value that is in cell A1 in my worksheet and put it in a document at a certain point (using a bookmark).

I can open my document but I'm trying to make the cell a variable (string), and print it in/after the bookmark.

I have some coding experience from about 7 years ago so if it could be explained in the simplest way possible that'd be ideal.

The Cell is A1 Name of Bookmark is "Earth" Value in the Cell is World

Here's my code so far

Private Sub CreateWordDoc()
Dim wdApp As Word.Application
Set wdApp = New Word.Application
Dim Cell As String
Range("A1").Value = Cell

With wdApp
.Visible = True
.Activate
.Documents.Add "C:\Users\Desktop\WordBookmarkTest.docx"


wdApp.Activate
End With
End Sub 

I don't know if that makes sense. Like I said, my coding experience is from A Level Computer Science 7 years ago.

Answer 1

Like this:

Private Sub PopulateWordDoc()
    
    Dim wdApp As Word.Application, doc As Word.Document, ws As Worksheet
    
    Set ws = ThisWorkbook.Worksheets("Values") 'for example
    Set wdApp = New Word.Application
    With wdApp
        .Visible = True
        .Activate
        'get a reference to the opened document
        Set doc = .Documents.Open("C:\Users\Desktop\WordBookmarkTest.docx")
        'populate bookmark "Earth" in `doc`
        AddTextToBookmark doc, "Earth", ws.Range("A1").Value 
    End With
    
End Sub

'Add text `txt` to bookmark `bmName` in document `doc`
'Adding the text deletes the bookmark, so recreate it
Sub AddTextToBookmark(doc As Word.Document, bmName As String, txt)
    Dim rng As Word.Range
    Set rng = doc.Bookmarks(bmName).Range 'get the range of the bookmark
    rng.Text = txt                        'add the text
    doc.Bookmarks.Add bmName, rng         'recreate the bookmark
End Sub