搜索数字和度数符号

Question

I have a worksheet that needs to classify elbows based on their degrees but also has a lot of other material in it. I'm using VBA. I can't just use a Like or InStr function to search 45, 90, etc. because it is returning other material. I have used the following to find the degree symbol and the number but it is returning values if they occur in the cell at all, not necessarily if they are right next to each other. So if I have data in the cell that says "Qty 90 of 45° elbows" and "Qty 45 of 90° elbows" it is causing issues.

For Each cell In Range("A1:A5000")
If InStr(cell.Value, ChrW(176)) > 0 And cell Like "*45*" Then
    cell.Offset(0,5).Value = "45 Degree"
End If
Next cell

I figure I can do a work around and try to extract info from the cell, enter it into another one, and then search on that. But that's a pain. Any ideas?

Answer 1

The Instr and Like operator are not mutually excluding which means you are getting "false positives". Why not just a single Like statement:

Sub Test()

Dim arr As Variant: arr = Array("Qty 90 of 45° elbows", "Qty 45 of 90° elbows", "Qty 90 of 145° elbows")

'Using Like expressions:
For Each el In arr
    Debug.Print el Like "*45°*"
Next

'Using Regular expressions:
With CreateObject("vbscript.regexp")
    .Pattern = "(?:^|\D)45°(?:$|\D)"
    For Each el In arr
        Debug.Print .Test(el)
    Next
End With

End Sub

I'm not sure about your data and posibilities of degrees past 99. If possible you run the risk of false positives even with Like . Therefore I included an alternative in the code above to use a regular expression instead.

---

Extra: This is an assumption from my end, but it looks like you are trying to find the degrees (not just '45') and do some calculations or something alike? If so, you could alter the pattern a little too:

Sub Test()

Dim arr As Variant: arr = Array("Qty 90 of 45° elbows", "Qty 45 of 90° elbows", "Qty 90 of 145° elbows")

With CreateObject("vbscript.regexp")
    .Global = True
    .Pattern = "^.*?(\d+)°.*$"
    For Each el In arr
        Debug.Print Val(.Replace(el, "$1"))
    Next
End With

End Sub