使用 awk 追加到当前行的上方

Question

I have a text files where the some text from the first field rolls over onto the next row.

Example

Company Name LLC
Company Name2
LLC
Very Good company name but rolls
over

I am able to get the rows that have rolled over by

awk '{ if (NF ==1) print $0}'

I am looking for a way to append the text onto (NR -1)

correct output

Company Name LLC
Company Name2 LLC
Very Good company name but rolls over

Answer 1

awk -v ORS= '
    NR>1 { print NF>1 ? "\n" : OFS }
    1;
    END{ print "\n" }
' input_file

• unset ORS so print doesn't emit implicit newlines
• on every line except the first print appropriate delimiter ( OFS on overflow, otherwise newline)
• print the actual line
• at the end, print a newline

Answer 2

With your shown samples and attempts please try following tac + awk code.

tac Input_file | 
awk '
NF==1{
  val=$0(val?OFS val:"")
  next
}
NF>1{
  print $0,val
  val=""
}' | 
tac

Answer 3

Preliminarily, you are not making use of awk's pattern-action syntax and defaults; awk NF==1 has the same effect as the command you posted.

But for your Q, in awk you need to buffer the previous line and then decide how to use it:

awk 'NF==1{print p,$0; p=""; next} length(p){print p} {p=$0} END{print p}'

Or less efficiently but simpler you can do

tac | awk 'NF==1{getline t; print t,$0; next} 1' | tac

Answer 4

I would use GNU AWK for this task following way let file.txt content be

Company Name LLC
Company Name2
LLC
Very Good company name but rolls
over

then

awk 'BEGIN{RS=ORS=""}{print gensub(/\n([^[:space:]]+)(\n|$)/, " \\1\\2", "g")}' file.txt

gives output

Company Name LLC
Company Name2 LLC
Very Good company name but rolls over

Explanation: I set RS to empty string so GNU AWK treat things between empty lines as rows, in this case whole content as single row. Then I use gensub function to replace runs of non-whitespace characters after newline character which do occupy whole line. Newline before such run is replaced using space. 1st capturing group is used to said non-whitespace characters, 2nd capturing group allows alternative as such run might be terminated by newline or end of file, whatever it was it is used as replacement value. Disclaimer : this solution assumes empty (blank) line is never present in your file.

(tested in gawk 4.2.1)

Answer 5

awk '
    {NF>1 ? a[NR]=$0 : a[NR-1]=a[NR-1] FS $1}
    END{for(i in a) print a[i]}
' file

Company Name LLC
Company Name2 LLC
Very Good company name but rolls over

• NF>1 if more than one field
  • true: a[NR]=$0 add element (line) to array
  • false: a[NR-1]=a[NR-1] FS $1 update prev-array-element NR-1
• for(i in a) print a[i] print all array-elements

Answer 6

$ awk 'NR>1{printf "%s%s", prev, (NF==1 ? OFS : ORS)} {prev=$0} END{print prev}' file
Company Name LLC
Company Name2 LLC
Very Good company name but rolls over