通过字符串中的字符和 XSLT 中的节点进行双重迭代 - 如何使用递归进行？

Question

I need to replace some characters in a string stored in <p> with <app> nodes which contain a matching char (or substring) in a child element <lem> . Each <app> contains only one <lem> at the top, and an arbitrary number of other nodes below it. Each <app> only refers to a single character in the text, and they are placed in order.

I am new to XSLT, and cannot come up with a good recursion to do this -- I'm kind of stuck in the java or MATLAB mindset of iterating over i = 1:n and j= 1:m , and I understand that this is no good for taking advantage of recursion in XSLT... Thanks for your help!!!

<div>
            <p>SOMEWONDERFULOLDTEXT</p>
            <app>
               <lem>O</lem>
               <rdg>Ø</rdg>
            </app>
            <app>
               <lem>W</lem>
               <rdg>V</rdg>
            </app>
            <app>
               <lem>O</lem>
               <rdg>Ö</rdg>
            </app>
            <app>
               <lem>E</lem>
               <rdg>Ë</rdg>
               <rdg>ę</rdg>
            </app>
         </div>

My stylesheet so far is this, but I know it doesn't work because it is iterating through the text for every <app> , which is wrong.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:tei="http://www.tei-c.org/ns/1.0" xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs tei" version="3.0">

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*"/>
        </xsl:copy>
    </xsl:template>

    <!-- now build the apparatus -->
    <xsl:template match="tei:div">
        <xsl:param name="thisBlock" select="./tei:p/node()"/>
        <xsl:for-each select="tei:app">
            <xsl:variable name="thisApp" select="."/>
            <xsl:for-each
                select="tokenize(replace(replace($thisBlock, '(.)', '$1\\n'), '\\n$', ''), '\\n')">
                <xsl:choose>
                    <xsl:when test="$thisApp/tei:lem/text() = .">
                    <xsl:copy-of select="$thisApp"></xsl:copy-of>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates></xsl:apply-templates>
                </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

The result I want is the following, although I am getting a frightful mess with each <app> containing the variant readings of O printed for every single O in the text, regardless of order (of course, because I don't know how to iterate linearly along two "arrays")...

<div>
            <p>S<app>
               <lem>O</lem>
               <rdg>Ø</rdg>
            </app>ME<app>
               <lem>W</lem>
               <rdg>V</rdg>
            </app><app>
               <lem>O</lem>
               <rdg>Ö</rdg>
            </app>ND<app>
               <lem>E</lem>
               <rdg>Ë</rdg>
               <rdg>ę</rdg>
            </app>RFULOLDTEXT</p>
         </div>

Answer 1

I suppose this is one way you could look at it:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="div">
    <div>
        <p>
            <xsl:call-template name="process">
                <xsl:with-param name="string" select="p"/>
                <xsl:with-param name="app" select="app"/>
            </xsl:call-template>
        </p>
    </div>  
</xsl:template>

<xsl:template name="process">
    <xsl:param name="string"/>
    <xsl:param name="app"/>
    <xsl:choose>
        <xsl:when test="$app">
            <xsl:variable name="char" select="$app[1]/lem" />
            <xsl:value-of select="substring-before($string, $char)" />
            <xsl:copy-of select="$app[1]"/>
            <!-- recursive call -->
            <xsl:call-template name="process">
                <xsl:with-param name="string" select="substring-after($string, $char)"/>
                <xsl:with-param name="app" select="$app[position()>1]"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$string" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

This could probably be smartened up a bit in XSLT 3.0, but I prefer the clarity of the named template method.

Answer 2

The use of XSLT 3 and the request for a "recursive" approach while wanting to "iterate" makes me wonder whether xsl:iterate can help:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xpath-default-namespace="http://www.tei-c.org/ns/1.0"
    xmlns="http://www.tei-c.org/ns/1.0"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="div[p and app]">
    <xsl:copy>
      <p>
        <xsl:iterate select="app">
          <xsl:param name="text" select="p"/>
          <xsl:on-completion select="$text"/>
          <xsl:sequence select="substring-before($text, lem), 
                                .[contains($text, lem)]"/>
          <xsl:next-iteration>
            <xsl:with-param name="text" select="substring-after($text, lem)"/>
          </xsl:next-iteration>
        </xsl:iterate>
      </p>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

Answer 3

I don't think you need recursion, if I've understood what you're trying to do. Here's how I might attack the problem:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:tei="http://www.tei-c.org/ns/1.0" xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs tei" version="3.0"
    xpath-default-namespace="http://www.tei-c.org/ns/1.0">

  <xsl:template match="p/text()">
    <!-- find the apps that applies to the current text node -->
    <xsl:variable name="apps" select="ancestor::div/app"/>
    
    <!-- parse the text node into a sequence of 1-char strings
      This weird trick uses string-to-codepoints() to tokenize 
      the string into a sequence of character codepoints, and
      then uses codepoints-to-string() to turn each integer 
      codepoint back into a 1-char string, yielding a sequence
      of characters 
    -->
    <xsl:variable name="characters" select="
      for $codepoint in 
        string-to-codepoints(.) 
      return 
        codepoints-to-string($codepoint)
    "/>

    <!-- for each character, output a matching app if
      there is one, or otherwise the character itself
    -->
    <xsl:for-each select="$characters">
      <xsl:variable name="character" select="."/>
      <xsl:variable name="app" select="$apps[lem = $character]"/>
      <xsl:choose>
        <xsl:when test="$app">
          <xsl:copy-of select="$app"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="."/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
  </xsl:template>

  <!-- discard app elements -->
  <xsl:template match="app"/>

  <!-- copy everything else -->
  <xsl:mode on-no-match="shallow-copy"/>

</xsl:stylesheet>

Applied to:

<div xmlns="http://www.tei-c.org/ns/1.0">
  <p>SOMEWONDERFULOLDTEXT</p>
  <app>
     <lem>O</lem>
     <rdg>Ø</rdg>
  </app>
  <app>
     <lem>W</lem>
     <rdg>V</rdg>
  </app>
  <app>
     <lem>O</lem>
     <rdg>Ö</rdg>
  </app>
  <app>
     <lem>E</lem>
     <rdg>Ë</rdg>
     <rdg>ę</rdg>
  </app>
</div>

Produces result:

<div xmlns="http://www.tei-c.org/ns/1.0">
  <p>S<app>
     <lem>O</lem>
     <rdg>Ø</rdg>
  </app><app>
     <lem>O</lem>
     <rdg>Ö</rdg>
  </app>M<app>
     <lem>E</lem>
     <rdg>Ë</rdg>
     <rdg>ę</rdg>
  </app><app>
     <lem>W</lem>
     <rdg>V</rdg>
  </app><app>
     <lem>O</lem>
     <rdg>Ø</rdg>
  </app><app>
     <lem>O</lem>
     <rdg>Ö</rdg>
  </app>ND<app>
     <lem>E</lem>
     <rdg>Ë</rdg>
     <rdg>ę</rdg>
  </app>RFUL<app>
     <lem>O</lem>
     <rdg>Ø</rdg>
  </app><app>
     <lem>O</lem>
     <rdg>Ö</rdg>
  </app>LDT<app>
     <lem>E</lem>
     <rdg>Ë</rdg>
     <rdg>ę</rdg>
  </app>XT</p>
  
  
  
  
</div>