使用多数组计数？ （Excel，VBA）

Question

I have a relatively simple task and have already found a few solutions, but I have an idea that would be far more efficient, I just don't know if it's possible to code. Basically, I need to count animals, and their physical traits, then report on that data. Perhaps column A is for the species, B is for their hair color, and C is their age. I can solve this using a loop and nested if/else statements, but it balloons in size and looks very sloppy. What I had hoped to do was something more like:

Loop
    Array(species, color, age) = Array(species, color, age) + 1
End loop

This turns out to be very difficult though, as some of the values I'm getting are strings (species and color) and the array function only seems to accept numbers. Does anyone know of a way to count information like this in a very efficient manner? If I was able to store it in an array I could have been able to print all of the results at once, which was part of my goal.

Answer 1

You could use a Dictonary to tally up the occurrences of each combination. The Key would be a concatenated string of the species & color & age, and the item would be the count. You would code it very similarly to your idea:

Sub Example(ItemCollection As Variant)
    Dim Counts As Object
    Set Counts = CreateObject("Scripting.Dictionary")
    
    'Loop through your data set
    Dim Item As Variant
    For Each Item In ItemCollection
        Dim species As String, color As String, age As String
        'Define species, color and age based on each item from your data set
        'Maybe they are object members, or cells in a worksheet row
        'I don't know what your data looks like.
        
        Dim Key As String
        Key = species & "|" & color & "|" & age
        
        Counts(Key) = CLng(Counts(Key) + 1)
    Next
    
    'After the data has been tallied up, the dictionary "Counts", now contains the count of occurences of each combination.
    'You can see the full list of combinations by looking at the array Counts.Keys
    'You can return a specific count from the dictionary using the key: Counts(Key) where the Key is species & color & age
    'You can get the full list of counts from the dictionary by looking at the array Counts.Items
End Sub