检查范围内的所有单元格是否包含相同的值

Question

Can you help me with this Please, I'm trying to check if from range ("L2") to the end if result = "-" pop up a msgbox & colorize the range. the conditions is all the cells value in the range horizontally must be = "-"

Example of what I mean:

I try to the below code but it's colorized all the value ("-") in the range

Sheets("Cumulated BOM").Activate
Dim i As Long
Dim c As Long
Dim myRange As Range
Dim myCell As Range


Set myRange = Range("L2", Range("L" & Row.Count).End(xlUp))

For Each myCell In myRange
    c = c + 1
    If (myCell) = "-" Then
        myCell.Interior.Color = RGB(255, 87, 87)
        i = i + 1
    End If
Next myCell

Answer 1

Highlight Rows With All Their Cells Containing the Same Value

Option Explicit

Sub HighlightInvalidRows()

    ' Prepare.

    ' Reference the workbook ('wb').
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    ' Reference the worksheet ('ws').
    Dim ws As Worksheet: Set ws = wb.Worksheets("Cumulated BOM")
    
    ' Reference the range ('rg').
    Dim rg As Range
    Set rg = ws.Range("L2", "S" & ws.Cells(ws.Rows.Count, "L").End(xlUp).Row)
    
    ' Write the number of columns of the range to a variable ('CellsCount').
    Dim CellsCount As Long: CellsCount = rg.Columns.Count
    ' Each row of the range has this number of columns (cells).
    
    ' Remove all range colors.
    rg.Interior.Color = xlNone
    
    ' Combine the rows ('rrg') to be highlighted
    ' into the Highlight range ('hrg').
    
    ' Declare variables that appear for the first time in the following loop.
    Dim hrg As Range
    Dim rrg As Range
    Dim MatchCount As Long
    
    ' Loop through the rows of the range.
    For Each rrg In rg.Rows
        ' Write the number of appearances of the value in the current row
        ' to a variable ('MatchCount').
        MatchCount = Application.CountIf(rrg, "-")
        ' Compare the match count with the cells count.
        If MatchCount = CellsCount Then ' the numbers are equal
            ' Combine the current row into the highlight range.
            If hrg Is Nothing Then ' the first match
                Set hrg = rrg
            Else ' all other matches
                Set hrg = Union(hrg, rrg)
            End If
        'Else ' the numbers are not equal; do nothing
        End If
    Next rrg
        
    ' Highlight the rows (in one go) and inform.
    
    If hrg Is Nothing Then ' no matches found
        MsgBox "No invalid rows found.", vbInformation
    Else ' matches found
        hrg.Interior.Color = RGB(255, 87, 87)
        MsgBox "Invalid rows highlighted.", vbExclamation
    End If
    
End Sub