使用 Delphi 和 REST api 发送文件

Question

I need to write a Delphi program to test REST api. There are two parts: the first is sending messages (JSon, Edifact or pure text, which we call business messages). After some trial and error, I'm able to send messages. But I have problems with the second part, which is to send files as attachment (mainly pdf and jpeg). I test the API with POSTMAN without any problem, but when I try to "translate" the request in Delphi, I get a 400 Bad request status. Here is my code:

begin
  //the 'RespID' is generated by the API when sending the business message and is needed to link the message with the attachment(s)
  RespID := MyParams.Values['RespID'];
  // sendAttachments_endPoint =/messages/:messageId/attachments
  RESTrequest1.Resource := StringReplace(sendAttachments_endPoint, ':messageId', RespID, [rfReplaceAll]);
  NbrOfAttach := StrToInt(MyParams.Values['attachments']);

  for idx := 1 to NbrOfAttach do
    begin
      AttachName := MyParams.Values['attach_' + IntToStr(idx)];
      FileName := ExtractFileName(AttachName);

      ABytes := FileToByteArray(AttachName);
      SetString(TmpStr, PAnsiChar(@ABytes[0]), Length(ABytes));

      with RESTrequest1 do
        begin
          Body.ClearBody;
          Params.Clear;

          RESTrequest1.AddBody(TmpStr);

          //authentication works quite well and is used as is in other programs
          AddAuthParameter('api-key', authAPIkey, pkHTTPHEADER, [poDoNotEncode]);
          AddAuthParameter('Authorization', 'Bearer ' + JWToken, pkHTTPHEADER, [poDoNotEncode]);

          AParameter := RESTrequest1.Params.AddItem;
          //Filename parameter is required in the API header...
          AParameter.Name := 'Filename';
          AParameter.Value := FileName;
          AParameter.Kind := pkHTTPHEADER;

          AParameter := RESTrequest1.Params.AddItem;
          // as well as the edi-document-qualifier
          AParameter.Name := 'edi-document-qualifier';
          AParameter.Value := IntToStr(idx);
          AParameter.Kind := pkHTTPHEADER;
          AParameter.Options := [poDoNotEncode];

          AParameter := RESTrequest1.Params.AddItem;
          AParameter.Name := 'Content-Type';
          AParameter.Value := 'application/pdf';
          AParameter.Kind := pkHTTPHEADER;
          AParameter.Options := [poDoNotEncode];

          try
            Execute;
            REST_RepStatus := RESTresponse1.StatusCode;
            // REST_RepStatus = 400
            ...

The function FileToByteArray looks like this

function FileToByteArray(const FileName: WideString): TArray<Byte>;
const
  BLOCK_SIZE = 1024;
var
  BytesRead, BytesToWrite, Count: integer;
  F: file of Byte;
  pTemp: Pointer;
begin
  AssignFile(F, FileName);
  Reset(F);
  try
    Count := FileSize(F);
    SetLength(Result, Count);
    pTemp := @Result[0];
    BytesRead := BLOCK_SIZE;
    while (BytesRead = BLOCK_SIZE) do
      begin
        BytesToWrite := Min(Count, BLOCK_SIZE);
        BlockRead(F, pTemp^, BytesToWrite, BytesRead);
        pTemp := Pointer(LongInt(pTemp) + BLOCK_SIZE);
        Count := Count - BytesRead;
      end;
  finally
    CloseFile(F);
  end;
end;

instead of passing the content of the file as a string, I've tried to use a stream

var
fs: TFileStream;
...
fs := TFileStream.Create(AttachName, fmOpenRead);
...
RESTrequest1.AddBody(fs);

but no way, I always get a Bad Request

Answer 1

To send files through Delphi REST Client, you can just use the TRESTRequest's method "AddFile". With this simple method, you only need to specify the path to your file on the local drive or storage and his content type (there is a wide list of MIME types), without any need to do additional steps by yourself like: encoding the file to Base64, creating parameters with the kind "pkFILE", or setting the request's content type to "Multipart/formdata". There is also an overloaded version of this method where you can specify a unique name for identifying the file within the request content (similar to the ''Name'' attribute in an HTML form's ''Input'' elements), so as you can send multiple files with different content types in the same request without risk of overwriting. You can get further information about this method in the DocWiki.

And on the server side, you have to set the logic for retrieving and saving the file and even sending responses about the uploading result (whether it was done successfully or failed).

Here is a minimal code example for sending a Word document (check the content type):

procedure TForm1.BtnSendFileClick(Sender: TObject);
begin
  try
    try
    RESTRequest1.Method := TRESTRequestMethod.rmPOST;
    RESTRequest1.AddFile('File1', 'C:\Doc1.docx', TRESTContentType.ctAPPLICATION_VND_OPENXMLFORMATS_OFFICEDOCUMENT_WORDPROCESSINGML_DOCUMENT);
    RESTRequest1.Execute;
    except
    ShowMessage('Uploading failed');
    end;
  finally
  ShowMessage(RESTRequest1.Response.Content); //here our example server script will print "Uploaded successfully"
  end;
end;