使用 excel 中的默认标头转置

Question

I have a simple data which is

Name   Age
Venky   20
Anil    22

Output should be like:

Name : Venky
Age  : 20
Name : Anil
Age  : 22

Note: For each record should have header values

I have tried multiple ways apart from Macros Can you please give me you inputs?

Answer 1

Without more specific context we can play with BYROW HSTACK , REDUCE , TOCOL , ARRAYTOTEXT , TEXTSPLIT and SUBSTITUTE to get the expected result:

=LET(z,IF(ISNUMBER(SEQUENCE(ROWS(TOCOL(A1:B1)),1,1)),";",),y,
    SUBSTITUTE(ARRAYTOTEXT(BYROW(A2:B3, LAMBDA(x, SUBSTITUTE(SUBSTITUTE(
    REDUCE("", HSTACK(TOCOL(A1:B1), TOCOL(x), z), 
    LAMBDA(a,b, IF(a="", b, a & ":" & b))), 
    ":;:", ";"),":;", ";")))),";, ",";") , 
    TEXTSPLIT(LEFT(y, LEN(y) - 1),,";"))

The z variable is just a trick for generating a column array of constant values ( ; ) with the same size as the header, that we are going to use as row delimiter, maybe there is an easier way to do it, but this works.

IF(ISNUMBER(SEQUENCE(ROWS(TOCOL(A1:B1)),1,1)),";",)

The main idea is create on the fly for each row of input data( A1:B3 including the headers) a new array via HSTACK with the following structure (let's call it tempArray :

|Name | name1 |; |
------------------
|Age  | age1  |; |
------------------

Note : It should work for more than two columns in the header

Then reduce tempArray with REDUCE to concatenate each value with : . At this point each row x has been trasformed in to a string.

Clean the delimiter generated with SUBSTITUTE to remove unnecessary repeated delimiters. Then convert the entire Array generated by BYROW with ARRAYTOTEXT to a single string that has each row delimited by ; . Finally to remove the last ; generated via LEFT so we can use TEXTSPLIT to convert the result to a column array with the expected format.

It is a little bit tricky but if you do it step by step you can test it until you get the expected result. I don't think Excel provides a generic map function to convert from one format to another in the way you want it.

Disclaimer : I think the formula can be simplified using MAP function, so probably there is no need to deal with unnecessary delimiters created. I will update the answer in case it works.