如何在 Neo4j cypher 查询中使用模式理解对关系大小进行条件检查

Question

Using the following query I was able to make condition query statement based on relationship count.

WITH ( (:LABEL_X)<-[]-(:LABEL_Y) ) AS res
CALL apoc.do.when(size( res ) = 2,
    "MATCH (c:LABEL_Y)  RETURN c",
    "MATCH (mu:LABEL_X)<-[mr]-(c:LABEL_Y) RETURN mu,mr,c",
{res:res}) YIELD value
RETURN value

However, this shows warning lint as below

This feature is deprecated and will be removed in future versions.

A pattern expression should only be used in order to test the existence of a pattern. It should therefore only be used in contexts that evaluate to a boolean, eg inside the function exists() or in a WHERE-clause. All other uses are deprecated and should be replaced by a pattern comprehension.

So, please suggest a way to get same result using pattern comprehension. From the neo4j docs pattern comprehension, I see most of the things are in the RETURN statement. whereas, in my case I need to it before the apoc execution in order to decide on what query to execute in apoc.do.when call.

Or suggest if you know any other way to achieve this.

Answer 1

You can use it like this:

WITH [x = (:LABEL_X)<-[]-(:LABEL_Y) | x] AS res
CALL apoc.do.when(size( res ) = 2,
    "MATCH (c:LABEL_Y)  RETURN c",
    "MATCH (mu:LABEL_X)<-[mr]-(c:LABEL_Y) RETURN mu,mr,c",
{res:res}) YIELD value
RETURN value

Or simply calculate size directly, like this:

WITH size([x = (:LABEL_X)<-[]-(:LABEL_Y) | x]) AS numberOfPaths
CALL apoc.do.when( numberOfPaths  = 2,
    "MATCH (c:LABEL_Y)  RETURN c",
    "MATCH (mu:LABEL_X)<-[mr]-(c:LABEL_Y) RETURN mu,mr,c",
{numberOfPaths:numberOfPaths}) YIELD value
RETURN value

Answer 2

You are counting (via size) the number of relationships between LABEL_X and LABEL_Y. If the size equals 2 then you will return LABEL_Y else you will return LABEL_X, LABEL_Y and their relationships.

This expression:

size((:LABEL_X)<-[]-(:LABEL_Y)) 

is the same with

MATCH res=(:Price_Point)-[]-(:Headphone)  
WITH size(collect(relationships(res))) as res 

Thus below query will avoid the warning error about deprecation of pattern expression

MATCH res=(:LABEL_X)<-[]-(:LABEL_Y)
WITH size(collect(relationships(res))) as res
CALL apoc.do.when(
    res = 2,
    "MATCH (c:LABEL_Y)  RETURN c",
    "MATCH (mu:LABEL_X)<-[mr]-(c:LABEL_Y) RETURN mu, mr, c",
    {}
    ) YIELD value
RETURN value

Note that I removed the param {res:res} because it is not used anyway. Parameters is a map while in your query res is a pattern expression which is a list of lists.