如何在异常情况下使用 VLOOKUP？

Question

To assign the office responsible for a certain country I use a VLOOKUP function. In this way, Office China is responsible for Country China, Office Germany for Country Germany, etc.

There are some cases, dependent on a license, that should be assigned to other Offices, not following the VLOOKUP function.

For example:

• License6 although in Country China, should be assigned to Office Germany
• License10 although in Country China, should be assigned to Office India

There are a number of exceptions. How do I build these exceptions into the VLOOKUP function?

Answer 1

You can use the following in cell D2 :

=IF(A2:A100="","",IFERROR(XLOOKUP(B2:B100,TB_Exceptions[License],
TB_Exceptions[Office]), IFERROR(XLOOKUP(C2:C100,
TB_CountryOffice[Country],TB_CountryOffice[Office]), 
"CASE NOT FOUND")))

or using LET function to facilitate maintenance of the formula:

=LET(nameRng, A2:A100, licRng,B2:B100, countryRng, C2:C100,
 IF(nameRng="","",IFERROR(XLOOKUP(licRng,TB_Exceptions[License],
 TB_Exceptions[Office]),IFERROR(XLOOKUP(countryRng,
 TB_CountryOffice[Country],TB_CountryOffice[Office]), 
 "CASE NOT FOUND")))
)

Explanation

We are using a nested XLOOKUP starting first with the most restricted search, ie the exceptions, and in case of #N/A then it looks for the regular country lookup table. We consider the CASE NOT FOUND as a last resort in case some lookup value was not defined.

We are using Excel Tables to have dynamic ranges in the lookup tables. For the initial data set we don't use it, because for Excel Tables Spilled array formulas aren't supported, ie it returns #SPILL! error.

We define the data input ranges larger than the actual input data set, in case we want to include additional data. We add the initial condition: IF(A2:A100="","",..) to treat the blank lines of the input table.