Cljfx：渲染器的工作原理

Question

I'm digging in Cljfx right now. But I faced a problem: can't understand how renderer exactly works. I want button's text will be changed after user pressed it. The initial state is "Button" text and it should be changed to "Pressed". But nothing happens like that. What I'm doing wrong?

(ns examp.core
  (:gen-class)
  (:require [cljfx.api :as fx])
  (:import [javafx.application Platform]))

(def *button-text (atom {:text "Button"}))

(def renderer
  (fx/create-renderer))

(defn label-text[& args]
  {:fx/type :label
   :text "Press the button"})

(defn root [& args]
  {:fx/type :stage
   :showing true
   :title "Cljfx"
   :width 300
   :height 300
   :scene {:fx/type :scene
           :root {:fx/type :v-box
                  :padding {:left 90 :top 19}
                  :spacing 10
                  :children [{:fx/type label-text}
                             {:fx/type :button
                              :min-width 50
                              :min-height 30
                              :text (:text @*button-text)
                              :on-action (fn [_]
                                           (if (= (:text @*button-text) "Button")
                                             (do
                                               (swap! *button-text assoc :text "Pressed")
                                               (println @*button-text)
                                               (renderer {:fx/type root}))
                                             (do
                                               (swap! *button-text assoc :text "Button")
                                               (println @*button-text)
                                               (renderer {:fx/type root}))))}]}}})


(defn -main [& args]
  (Platform/setImplicitExit true)
  (renderer {:fx/type root}))

Answer 1

If you don't find a Cljfx-specific solution, you can always use directly JavaFX functions. I used .setText :

{:fx/type :button
   :min-width 50
   :min-height 30
   :text "Click me!"
   :on-action (fn [event]
                (.setText (.getSource event) "Clicked!"))}

Or, if you want to alternate between two texts:

{:fx/type    :button
   :min-width  50
   :min-height 30
   :text       "Click me!"
   :on-action  (fn [event]
                 (let [source (.getSource event)]
                   (if (= (.getText source) "Click me!")
                     (.setText source "Clicked!")
                     (.setText source "Click me!"))))}

Answer 2

So I inspected examples of Cljfx code more attentively and found solution. This is how it works with renderer.

(ns examp.core
  (:gen-class)
  (:require [cljfx.api :as fx])
  (:import [javafx.application Platform]))

(def text {:text "click me"})

(def renderer (fx/create-renderer))


(defn root [{:keys [text]}]
  {:fx/type :stage
   :showing true
   :title "Window"
   :scene {:fx/type :scene
           :root {:fx/type :v-box
                  :children [{:fx/type :label
                              :text  "press the button"}
                             {:fx/type :button
                              :min-width 100
                              :min-height 50
                              :text text
                              :on-action (fn [_]
                                           (if (= text "click me") 
                                           (renderer
                                             {:fx/type root
                                              :text "clicked"})
                                           (renderer 
                                             {:fx/type root
                                              :text "click me"})))}]}}})

(defn -main [& args]
  (Platform/setImplicitExit true)
  (renderer {:fx/type root
             :text (:text text)}))