从 grep/awk 结果中提取 substring？

Question

I have a grep command that finds rows in a file, passes those to awk and prints out the 1st and 15th columns.

grep String1 /path/to/file.txt | grep string2 | awk -F ' ' '{print $1, $15}'

So far, so good. This results in a list like this:

2023-01-20 [text1]>
2023-01-22 [text2]>
2023-01-23 [text3]>
2023-01-25 [text4]>

Ideally, I'd like to add some regex to the awk command so that I get this:

2023-01-20 text1
2023-01-22 text2
2023-01-23 text3
2023-01-25 text4

My searches have only returned how to use regex with awk to identify fields but not to extract a substring from the results. Is this possible with awk or some other command?

Answer 1

One awk idea that combines the current code with the new requirement:

awk -v s1="String1" -v s2="string2" '                               # feed both search strings in as awk variables "s1" and "s2"
$0~s1 && $0~s2 { print $1,substr($15,2,index($15,"]")-2) }          # if s1 and s2 are both present in the current line then print 1st field and 15th field (sans the "[" "]" wrappers)
' /path/to/file.txt 

A non-sensical demo file:

$ cat file.txt
a b c d e f g h i j k l m n o p q r s t u v w x y z
a string2 c d e f g h i j k l m n [old]> p q r s t u v String1 x y z
a b c d e f g h i j k l m n o p q r s t u v w x y z
a String1 c d e f g h i j k l m n [older]> p q r s t u v string2 x y z

Running the awk script against this file generates:

a old
a older

Answer 2

Another option removing the leading [ and trailing ]> with gsub and an alternation:

awk '/String1/ && /string2/ {
  gsub(/^\[|\]>$/, "", $15)
  {print $1, $15}
}' file.txt

In gnu-awk you could use gensub :

awk '/String1/ && /string2/ {
  {print $1, gensub(/^\[|\]>$/, "", "g", $15)}
}' file

---

Or find the occurrence of the string using index:

awk 'index($0, "String1") && index($0, "string2"){
  gsub(/^\[|\]>$/, "", $15)
  {print $1, $15}
}' file

Answer 3

If you're just basically want to delete the characters [ , ] and > , you can simply use tr -d for this, something like:

... | tr -d "[]>"

Linux prompt>echo "2023-01-20 [text1]>" | tr -d "[]>"
2023-01-20 text1