qml CaptureSession 在 Android 上冻结应用程序

Question

I have a bug when using CaptureSession on Qt6.4, if I use it in a dynamic component, when I destroy it, the app freezes and I have to kill it. This problem does not exist when I compile for Desktop. I tried on Android 11 & 13, the result is the same.

Also it was perfectly working with Qt5 when only using VideoOuput & Camera.

I wrote a minimal example using a Loader, that creates the freeze. If someone has an idea to fix it:

import QtQuick 6.4
import QtQuick.Window 6.4
import QtQuick.Controls 6.4
import QtMultimedia

ApplicationWindow
{
id: window
visible: true
width: Screen.desktopAvailableWidth
height: Screen.desktopAvailableHeight

Loader {
    id: loader
    anchors.fill: parent
    active: activeBtn.checked
    sourceComponent: Component {
        Item {
            id: item

            Camera {
                id: camera
                active: true
                focusMode: Camera.FocusModeAutoNear
            }

            CaptureSession {
                camera: camera
                videoOutput: videoOutput
            }

            VideoOutput {
                id: videoOutput
                anchors.fill: parent

                fillMode: VideoOutput.Stretch
            }
        }
    }
}


Button {
    id : activeBtn
    text: "Active CAM"
    checkable: true
    anchors {
        right: parent.right
        bottom: parent.bottom
    }
}
}

The app freezes as soon as I unload the component, so when CaptureSession is destroyed.

Answer 1

I would make sure the Camera is stopped before destroying the Component .

In other words, we need to acknowledge on some backends, the camera may be running in a different thread, and, we must make sure we give it sufficient time to terminate the camera and the corresponding VideoOutput preview before forcibly destroying the QML components.

We can keep your original property binding for starting the camera, ie

    property bool cameraActive: false
    Loader {
        id: loader
        anchors.fill: parent
        active: activeBtn.checked || cameraActive

So that will create the component as soon as the Button is checked, HOWEVER, during the initialization of the Component , we changed cameraActive = true; so that it prevents the unchecking of the same Button to destroy the component.

                Component.onCompleted: {
                    cameraActive = true;
                }

We use that Button event to stop the Camera with camera.stop() .

                Connections {
                    target: activeBtn
                    function onCheckedChanged() {
                        if (!activeBtn.checked && camera.active) {
                            camera.stop();
                        }
                    }
                }

As soon as we know the Camera has stopped with camera.active === false , then, we change cameraActive = false and that should resume the destruction of your Component .

                Camera {
                    id: camera
                    active: true
                    focusMode: Camera.FocusModeAutoNear
                    onActiveChanged: cameraActive = active
                }

Here's your complete code with all of the above changes. Note that I haven't been able to fully verify the code below, so, please treat the code as an educational guide only:

import QtQuick 6.4
import QtQuick.Window 6.4
import QtQuick.Controls 6.4
import QtMultimedia

ApplicationWindow
{
    id: window
    visible: true
    width: Screen.desktopAvailableWidth
    height: Screen.desktopAvailableHeight
    property bool cameraActive: false

    Loader {
        id: loader
        anchors.fill: parent
        active: activeBtn.checked || cameraActive
        sourceComponent: Component {
            Item {
                id: item
                
                Camera {
                    id: camera
                    active: true
                    focusMode: Camera.FocusModeAutoNear
                    onActiveChanged: cameraActive = active
                }
                
                CaptureSession {
                    camera: camera
                    videoOutput: videoOutput
                }
                
                VideoOutput {
                    id: videoOutput
                    anchors.fill: parent
                    
                    fillMode: VideoOutput.Stretch
                }

                Connections {
                    target: activeBtn
                    function onCheckedChanged() {
                        if (!activeBtn.checked && camera.active) {
                            camera.stop();
                        }
                    }
                }

                Component.onCompleted: {
                    cameraActive = true;
                }
            }
        }
    }
    
    Button {
        id : activeBtn
        text: "Active CAM"
        checkable: true
        anchors {
            right: parent.right
            bottom: parent.bottom
        }
    }
}