Drools 规则的执行次数超过预期

Question

I'm new to Drools and am following along the book: Mastering JBoss Drools 6

Chapter 2 shows an example where we create a Customer and Order , classify customers based on their order size, give discounts and generate Coupon s.

The example mentions:

• A customer
• The customer has an order with 5 items and therefore classified as a SILVER customer
• Each item costs more than 500, so it is classified as a HIGH_RANGE item
• The customer is a SILVER customer therefore a Coupon is created
• Give a discount of 10% for each SILVER customer with orders with more than 2 items

Here are the Drools rules:

add-discount.drl

rule "High Range order - 10% discount"
    when
        $o: Order($lines: orderLines, orderLines.size >= 2, $customer: customer, discount == null)
        $c: Customer(category == Customer.Category.SILVER, this == $customer)
        forall(
            OrderLine(this memberOf $lines, $item: item)
            Item(this == $item, category == Item.Category.HIGH_RANGE)
        )
    then
        modify($o){
            setDiscount(new Discount(10.0))
        }
end

classify-customer-rules.drl

rule "Classify Customer by order size"
    when
        $o: Order( orderLines.size >= 5, $customer: customer )
        $c: Customer(this == $customer, category == Customer.Category.NA)
    then
        modify($c){
            setCategory(Customer.Category.SILVER)
        }
end

classify-items-rules.drl

rule "Classify Item - Low Range"
    when
        $i: Item(cost < 200, category == Category.NA)
    then
        $i.setCategory(Category.LOW_RANGE);
        update($i);
end

rule "Classify Item - Mid Range"
    when
        $i: Item(cost > 200 && cost < 500, category == Category.NA)
    then
        $i.setCategory(Category.MID_RANGE);
        update($i);
end

rule "Classify Item - High Range"
    when
        $i: Item(cost >= 500, category == Category.NA)
    then
        $i.setCategory(Category.HIGH_RANGE);
        update($i);
end

coupons-creation.drl

rule "Create Coupons for silver customer"
    when
        $o: Order($customer: customer)
        $c: Customer(this == $customer, category == Customer.Category.SILVER)
    then
        Coupon x = new Coupon($c, $o, Coupon.CouponType.POINTS);
        System.out.println(x);
        insert(x);
end

The number of rules executed should be 8. 5 items to classify (5 rules) + 1 customer to classify (1 rule) + 1 discount to add (1 rule) + 1 coupon to create (1 rule)

But the actual number of rules fired is 9. Here is the test I used to check. The coupon creation rule is fired twice. I do not understand why. I checked the number of coupons created after firing the rule like so:

Collection<Coupon> coupons = Util.getFactsFromSession(kieSession, Coupon.class);
coupons.forEach(x -> System.out.println(x));

and I also have a print statement in the coupon creation rule.

This is what I get:

12:54:47.607 [main] DEBUG org.drools.core.impl.KnowledgeBaseImpl - Starting Engine in PHREAK mode
12:54:47.730 [main] DEBUG org.drools.core.common.DefaultAgenda - State was INACTIVE is nw FIRING_ALL_RULES
12:54:47.732 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
12:54:47.795 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
Coupon created com.example.droolstut.model.Coupon@b14cb989
12:54:47.797 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
12:54:47.797 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
12:54:47.799 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
12:54:47.806 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
Coupon created com.example.droolstut.model.Coupon@424f842a
12:54:47.806 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
12:54:47.806 [main] DEBUG org.drools.core.common.DefaultAgenda - Fire Loop
12:54:47.806 [main] DEBUG org.drools.core.common.DefaultAgenda - State was FIRING_ALL_RULES is nw HALTING
12:54:47.806 [main] DEBUG org.drools.core.common.DefaultAgenda - State was HALTING is nw INACTIVE
Coupon found: com.example.droolstut.model.Coupon@424f842a
Coupon found: com.example.droolstut.model.Coupon@424f842a

So, it looks like the rule is executed twice, but only the second coupon is found post execution.

But, when I run the test in debug mode, the coupon rule is executed only once, and the total number of rules fired is 8 too.

Did I miss something? I'd appreciate any help.

Answer 1

By the time a book on Drools gets published, it's out of date. Drools has fantastic documentation that you should be using as your primary source, not a very old book on a very old version of Drools. (Current version of Drools is Drools 8. Your book is for Drools 6.)

The other reason I recommend people not use books is because they tend to be awful. This one is no exception

---

The reason you're firing more rules than you think is because both "High Range order - 10% discount" forces a reevaluation of working memory, and "Create Coupons for silver customer" doesn't have anything to stop it from triggering multiple times.

"High Range..." calls 'modify' which re-fires all rules with the modified item. Since "Create Coupon..." remains valid to fire, it will trigger twice. (It'll fire once, and then once "High Range..." forces the reevaluation of working memory, it'll fire a second time.) You'll also see that there's twice as many coupons in working memory as you'd expect -- there will be 2 coupons instead of one because you fired the coupon rule twice.

To keep this from happening, you need to make "Create Coupon..." not valid to fire twice. (That is, once it's fired, it can't be triggered again.) You can do this, for example, by not allowing two of the same coupon. Or you could do this by only allowing one coupon. Depends on your use case.

One way might be:

rule "Create Coupons for silver customer"
when
  $o: Order($customer: customer)
  $c: Customer(category == Customer.Category.SILVER)

  // don't fire if this coupon already exists; I guessed on the variable names
  not( Coupon( customer == $c, order == $o, type == Coupon.CouponType.POINTS) )
then
  Coupon x = new Coupon($c, $o, Coupon.CouponType.POINTS);
  insert(x);
end

---

In the Real World, you want to keep your rules simple. Don't stick the entire kitchen sink into a single KieBase. The single responsibility principle is key here. Your "Item classification" rules should be fired separately from your customer classification rules should be fired separately from your discount rules.

Also calling update is a great way to get yourself into infinite loops and greatly increase your memory/cpu overhead. At my last company it was considered not only a code smell and bad practice, but actually outright banned (we checked for it in code reviews.)