CROSSOVER 和 CROSSUNDER 之间的最高值和最低值

Question

My objective is to conduct a technical analysis of the MACD line and signal line. To achieve this, the following methodology has been established:

1.Upon the occurrence of a bullish crossover between the MACD line and signal line, the minimum value of the closing price within the defined range should be plotted. The range is identified as the interval between the preceding bearish cross-under, which serves as the start point, and the current bullish crossover, which serves as the end point. 2.In the event of a bearish cross-under between the MACD line and signal line, the highest value of the closing price within the specified range should be plotted. The range is determined as the interval between the preceding bullish crossover, which serves as the start point, and the current bearish cross-under, which serves as the end point.

//I tried this code, however, the code sets lowprice and highPrice to low 1 and high 1 in the //global scope, so it will always be set to these values, regardless of the outcome of the if //statements. I also tried replacing the '=' with ':=" in the if statement and ended up with an //error saying invalid value of the 'length' argument in the "lowest" function. it must be >0. THE IMAGE IS AN EXAMPLE OF WHAT I WANT This //is my code. Any help would be appreciated as I am losing my mind.

//@version=4
study("Ultimate Code3", overlay=true)

// MACD Calculation
macdLine = ema(close, 12) - ema(close, 26)
signalLine = sma(macdLine, 9)

// MACD Crossover Detection
crossOver = crossover(macdLine, signalLine)
crossUnder = crossunder(macdLine, signalLine)

// Initialize variables for lowPrice and orange line
lowPrice = low[1]
highPrice = high[1]
var line lowLine = na
var line highLine = na

// Check for crossover and set lowPrice and orange line
if crossUnder
    barsSinceCrossOver = barssince(crossOver)
    if barsSinceCrossOver == 0
        highPrice = high
    else
        lowPrice = lowest(low, barsSinceCrossOver)
        highPrice = highest(high, barsSinceCrossOver)
    line.delete(lowLine)
    line.delete(highLine)
    highLine := line.new(bar_index, highPrice, bar_index+1, highPrice, width=2, color=color.red, extend=extend.both, style=line.style_dashed)

if crossOver
    barsSinceCrossUnder = barssince(crossUnder)
    if barsSinceCrossUnder == 0
        lowPrice = low
    else
        lowPrice = lowest(low, barsSinceCrossUnder)
        highPrice = highest(high, barsSinceCrossUnder)
    line.delete(lowLine)
    line.delete(highLine)
    lowLine := line.new(bar_index, lowPrice, bar_index+1, lowPrice, width=2, color=color.green, extend=extend.both, style=line.style_dashed)

bgcolor(crossOver  ? color.green : na, transp=80)
bgcolor(crossUnder ? color.red   : na, transp=80)

Answer 1

This works. Important to make sure bars_count can never be zero or less than zero, so that the ta.lowest & ta.highest functions work properly.

//@version=5
indicator('Ultimate Code3', overlay=true, max_lines_count = 10)

// MACD Calculation
macdLine = ta.ema(close, 12) - ta.ema(close, 26)
signalLine = ta.sma(macdLine, 9)

// MACD Crossover Detection
crossOver = ta.crossover(macdLine, signalLine)
crossUnder = ta.crossunder(macdLine, signalLine)
cross = ta.cross(macdLine, signalLine)
_sinceCross = ta.barssince(cross[1])

bars_count = ta.barssince(cross[1] )
bars_count:=nz(bars_count)
if bars_count<=0
    bars_count:=1
Highest = ta.highest(bars_count)

crossOverTime=ta.valuewhen(crossOver, time, 0)
crossUnderTime=ta.valuewhen(crossUnder, time, 0)

bool underToOver = time>= crossUnderTime and time<= crossOverTime
bool overToUnder = time>= crossOverTime and time<= crossUnderTime

float lowest = ta.lowest(bars_count)
float highest = ta.highest(bars_count)
_line1 = line(na)
_line2 = line(na)
if underToOver  
    if overToUnder[1]
        line.delete(_line1[1])
    _line1:=line.new(crossUnderTime, lowest, crossOverTime, lowest, xloc=xloc.bar_time, color = color.red, width = 2, extend = extend.none)

if overToUnder  
    if underToOver[1]
        line.delete(_line2[1])
    _line2:=line.new(crossOverTime, highest, crossUnderTime, highest, xloc=xloc.bar_time, color = color.blue, width = 2)

bgcolor(crossOver ? color.new(color.green, 80):na)
bgcolor(crossUnder ? color.new(color.red, 80):na)