将字符串与单词列表匹配

Question

Say I have the string "i zipped the fezz and it blipped like a baa" and I have an array of words (moo, baa, zip, fjezz, blaa) that I wanted to test to see it they're contained in the string, is there a way of doing so without either using | in the regex or iterating over each word?

TIA

Answer 1

If you're using Perl 5.10, you can use the smart match operator:

my @words = qw/moo bar zip fjezz blaa/;
if ( @words ~~ $str ) { 
    # it's there
}

The above will do an equality check (equivalent to grep $_ eq $str, @words ). If you want a regex match, you can use

if ( @words ~~ /$str/ )

Otherwise, you're stuck with grep or first from List::Util :

if ( grep { $str =~ /$_/ } @words ) { 
    ...
}

Answer 2

Given your desire to extract the matches as you indicate in a comment to @friedo's answer, I am confused as to why you want to avoid alternation:

use strict; use warnings;

use Regex::PreSuf;

my $str = 'i zipped the fezz and it blipped like a baa';

my $re = presuf(qw(moo baa zip fjezz blaa));

my @matches = $str =~ /($re)/g;

print "@matches\n";

Output:

zip baa

Or, do you want the words in the original sentence that match?

use strict; use warnings;

use Regex::PreSuf;

my $re = presuf(qw(moo baa zip fjezz blaa));

my $str = 'i zipped the fezz and it blipped like a baa';

my @matches = grep { /$re/ } split /\s+/, $str;

print "@matches\n";

Output:

zipped baa

Answer 3

I'd use grep or map and a regular expression to find matches. This brings greater control and flexibility about the matching condition. For example the following code checks if any of the words contained in the list @words is found as an entire word in the string $str :

use strict; use warnings;

my $str = "i zipped the fezz and it blipped like a baa";
my @words = qw/moo baa zip fjezz blaa/;

my @found = grep { $str =~ /\b$_\b/ } @words;
if ( @found )  { 
    print join(",", @found) . "\n";
}

will output:

baa

If you are only looking for partial word matches in $str , drop the word boundary assertions \\b from the regular expression, ie replace the respective line above with the following code:

my @found = grep { $str =~ /$_/ } @words;

and it will output:

baa,zip

If you rather want the words in the original string '$str' that match, use map and modify the regular expression as follows:

my @found = map { $str =~ /(\b\w*?$_\w*?\b)/ ? $1 : () ; } @words;

will output:

baa,zipped

I also want to mention the operator ~~ as it described in the accepted answer. If you're using at least Perl 5.10.1, you can use the smart match operator to find entire word matches. The following code smartmatches each word from string $str against the list of words @words . The smartmatch will do a comparison based on string equality:

my @found = grep { $_ ~~ @words } split(/\s+/, $str) ;

and output:

Smartmatch is experimental at ./a.pl line 7.
baa

The smartmatch operator ~~ was first available in Perl 5.10.1. Starting with Perl 5.18, smartmatch has been marked as experimental and if you use it, a warning will be issued to this effect. Additionally, smartmatch behavior has changed between 5.10.0 and 5.10.1. The code example provided in the " accepted answer " is based on 5.10.0 syntax which is obsolete (see dreagtun's comment).

Note: You therefore might consider smartmatching as a "non stable" Perl feature.

PS: At first, I rewrote the accepted answer but my changes were rejected as being too drastic. Therefore I posted my own answer.