Perl - 如何从标题的 FROM 部分获取电子邮件地址？

Question

I am trying to set up this script for my local bands newsletter.

Currently, someone sends an email with a request to be added, we manually add it to newsletter mailer I set up. (Which works great thanks to help I found here!)

The intent now is to have my script below log into the email account I set up for the list on our server, grab the info to add the email automatically.

I know there are a bunch of apps that do this but, I want to learn myself.

I already have the "add to list" working when there is an email address returned from the header(from) below BUT, sometimes the header(from) is a name and not the email address ( eg "persons name" is returned from persons name<email@address> but, not the <email@address> .)

Now, I am not set in stone on the below method but, it works famously... to a point.

I read all the docs on these modules and there was nothing I could find to get the darn email in there all the time.

Can someone help me here? Verbose examples are greatly appreciated since I am struggling learning Perl.

 #!/usr/bin/perl -w
    ##########
    use CGI;
    use Net::IMAP::Simple;
    use Email::Simple;
    use IO::Socket::SSL; #optional i think if no ssl is needed
    use strict;
    use CGI::Carp qw(fatalsToBrowser warningsToBrowser);
    ######################################################
    # fill in your details here
    my $username = '#########';
    my $password = '#############';
    my $mailhost = '##############';
    #######################################################
    print CGI::header();
    # Connect
    my $imap = Net::IMAP::Simple->new($mailhost, port=> 143, use_ssl => 0, ) || die "Unable to connect to IMAP: $Net::IMAP::Simple::errstr\n";
    # Log in
     if ( !$imap->login( $username, $password ) ) {
      print STDERR "Login failed: " . $imap->errstr . "\n";
      exit(64);
     }
    # Look in the INBOX
    my $nm = $imap->select('INBOX');
    # How many messages are there?
    my ($unseen, $recent, $num_messages) = $imap->status();
    print "unseen: $unseen, <br />recent: $recent, <br />total: $num_messages<br />\n\n";
    ## Iterate through unseen messages
     for ( my $i = 1 ; $i <= $nm ; $i++ ) {
         if ( $imap->seen($i) ) {
         my $es = Email::Simple->new( join '', @{ $imap->top($i) } );
         printf( "[%03d] %s\n\t%s\n", $i, $es->header('From'), $es->header('Subject'));
         print "<br />";
         next;
         }## in the long version these are pushed into different arrays for experimenting purposes
       else {
       my $es = Email::Simple->new( join '', @{ $imap->top($i) } );
       printf( "[%03d] %s\n\t%s\n", $i, $es->header('From'), $es->header('Subject'));
       print "<br />";
       }
     }
    # Disconnect
    $imap->quit;
    exit;

Answer 1

use Email::Address;
my @addresses = Email::Address->parse('persons name <email@address>');
print $addresses[0]->address;

The parse method returns an array, so the above way works for me.

Answer 2

I'm making this a separate answer because even though this information is hidden in the comments of the accepted answer, it took me all day to figure that out.

First you need to get the From header using something like Email::Simple. THEN you need to extract the address portion with Email::Address.

use Email::Simple;
use Email::Address;

my $email = Email::Simple->new($input);
my $from = $email->header('From');
my @addrs = Email::Address->parse($from);
my $from_address = $addrs[0]->address;    # finally, the naked From address.

Those 4 steps in that order.

The final step is made confusing by the fact that Email::Address uses some voodoo where if you print the parts that Email::Address->parse returns, they will look like simple strings, but they are actually objects . For example if you print the result of Email::Address->parse like so,

my @addrs = Email::Address->parse($from);
foreach my $addr (@addrs) { say $addr; }

You will get the complete address as output:

"Some Name" <address@example.com>

This was highly confusing when working on this. Granted, I caused the confusion by printing the results in the first place, but I do that out of habit when debugging.