Groovy读取目录中的最新文件

Question

I just have a question about writing a function that will search a directory for the most recent log in a directory. I currently came up with one, but I'm wondering if there is a better (perhaps more proper) way of doing this.

I'm currently using hdsentinel to create logs on computer and placing the log in a directory. The logs are saved like so:

/directory/hdsentinel-computername-date

ie. C:/hdsentinel-owner-2010-11-11.txt

So I wrote a quick script that loops through certain variables to check for the most recent (within the past week) but after looking at it, I'm question how efficient and proper it is to do things this way.

Here is the script:

String directoryPath = "D:"
def computerName = InetAddress.getLocalHost().hostName
def dateToday = new Date()
def dateToString = String.format('%tm-%<td-%<tY', dateToday)
def fileExtension = ".txt"
def theFile


for(int i = 0; i < 7; i++) {
    dateToString = String.format('%tY-%<tm-%<td', dateToday.minus(i))
    fileName = "$directoryPath\\hdsentinel-$computerName-$dateToString$fileExtension"

    theFile = new File(fileName)

    if(theFile.exists()) {
        println fileName
        break;
    } else {
        println "Couldn't find the file: " + fileName
    }
}

theFile.eachLine { print it }

The script works fine, perhaps it has some flaws. I felt I should go ahead and ask what the typical route is for this type of thing before I continue with it.

All input is appreciated.

Answer 1

Though a bit messy, you could implement a multi-column sort via the 'groupBy' method (Expounding on Aaron's code)..

def today = new Date()
def recent = {file -> today - new Date(file.lastModified()) < 7}

new File('/yourDirectory/').listFiles().toList()
.findAll(recent)
.groupBy{it.name.split('-')[1]}
.collect{owner, logs -> logs.sort{a,b -> a.lastModified() <=> b.lastModified()} }
.flatten()
.each{ println "${new Date(it.lastModified())}  ${it.name}" } 

This finds all logs created within the last week, groups them by owner name, and then sorts according to date modified.

If you have files other than logs in the directory, you may first need to grep for files containing 'hdsentinel.'

I hope this helps.

EDIT: From the example you provided, I cannot determine if the least significant digit in the format:

C:/hdsentinel-owner-2010-11-11.txt

represents the month or the day. If the latter, sorting by file name would automatically prioritize by owner, and then by date created (without all of the chicanery of the above code).

For Instance:

new File('/directory').listFiles().toList().findAll(recent).sort{it.name}

Answer 2

Hopefully this helps some..This sorts a given path by date modified in a groovier way. The lists them out.

you can limit the list, and add other conditions in the closure to get the desired results

 new File('/').listFiles().sort() {
   a,b -> a.lastModified().compareTo b.lastModified()
 }.each {
     println  it.lastModified() + "  " + it.name
 } 

Answer 3

As I was trying to solve a similar problem, learnt a much cleaner approach.

Define a closure for sorting

def fileSortCondition = { it.lastModified() }

And File.listFiles() has other variation which accepts FileFilter and FilenameFilter in Java, and these interfaces has a single method called accept, Implement the interface as a closure.

def fileNameFilter = { dir, filename ->
if(filename.matches(regrx))
    return true
else
    return false
} as FilenameFilter

And lastly

new File("C:\\Log_Dir").listFiles(fileNameFilter).sort(fileSortCondition).reverse()

Implement FileFilter interface if filtering is to be done by File attributes.

def fileFilter = {  file ->
        if(file.isDirectory())
             return false 
        else
            return true }  as FileFilter