如何为州动态创建Flex 4 AddChild操作？

Question

I have an application in which I need to create mx.states.State objects on the fly, as I'm reading external data in order to create the states. Each State only has a single child, so here's my code which I was using to accomplish this:

var state:State = new State();
state.name = "a";
state.overrides = [new AddChild(parent, DisplayObject(view))];
this.states.push(state);

However, when I actually change a state, I get a runtime error relating to the fact that you can't call addChild on a spark.components.Group component. Is there an equivalent AddElement action for adding elements to a Group during a state change?

Answer 1

You'll have to use the AddItems class for spark elements. I have provided an answer to a similar question before, it might be helpful.

Answer 2

Solution was simple, but a big question remains: why doesn't the Flex SDK include a class like this by default? And how does Flex 4 accomplish this without using a class like below?

In any case, here's the class.

package mx.states {
    import mx.core.IVisualElementContainer;
    import mx.core.IVisualElement;
    import mx.core.UIComponent;
    import mx.states.IOverride;
    import mx.utils.OnDemandEventDispatcher;

    /**
     * @author rfkrocktk
     */
    public class AddElement extends OnDemandEventDispatcher implements IOverride {

        private var _target:IVisualElement;

        private var _relativeTo:IVisualElementContainer;

        public function AddElement(relativeTo:IVisualElementContainer = null,
                target:IVisualElement = null) {
            this.relativeTo = relativeTo;
            this.target = target;
        }

        public function initialize() : void {

        }

        public function apply(parent : UIComponent) : void {
            this.relativeTo.addElement(this.target);
        }

        public function remove(parent : UIComponent) : void {
            this.relativeTo.removeElement(this.target);
        }

        [Bindable]
        public function get target():IVisualElement {
            return _target;
        }

        public function set target(value:IVisualElement):void {
            _target = value;
        }

        [Bindable]
        public function get relativeTo() : IVisualElementContainer {
            return _relativeTo;
        }

        public function set relativeTo(relativeTo : IVisualElementContainer) : void {
            _relativeTo = relativeTo;
        }
    }
}