批处理文件 - 使用 ping 测试网络连接

Question

Using a batch file would it be possible to do something like:

ping google.com

if return success do ECHO You are connected to the internet

else return ECHO You are not connected to the internet

Answer 1

You can use following snippet:

@echo off
Ping www.google.de -n 1 -w 1000
if errorlevel 1 echo Not connected

Answer 2

Here's a script that will repeatedly check, and write the time (from system clock) and "internet offline" to a log file at C:\\Internet.txt each time the internet goes offline. Unfortunately the latest line in the log file will appear at the end - I don't know how to make it appear at the top ;)

BTW: I set the wait time (-w) to 20 seconds, because I was using a 3G dongle (with 2G internet) so 20s was often the only way to be sure if the internet was really down or something else was the problem... Feel free to change it to 5000 for 5s, or delete "-w 20000" altogether to leave it at default.

@echo off

:START

ping -n 4 4.2.2.2 -w 20000 >nul

if %errorlevel% == 1 (
  echo Internet offline >> C:\Internet.txt
  Time /t >> C:\Internet.txt
)

Timeout /t 30
@set errorlevel = 0

GOTO START

Answer 3

@echo off
echo Checking connection
ping -n 1 www.google.com >nul
if errorlevel 1 (
  cls
  echo Failed
  pause>nul
  exit
)

cls
echo Success!
pause>nul
exit

Answer 4

Based on the answer from @CShulz, here's a script that'll print "Not connected" only when there's no connection, else it'll silently loop through the test every 30 seconds. First ping tests for connectivity & prints an error message if there's a problem. The second ping adds a 30 second wait by pinging the localhost.

@echo off
:loop
ping www.google.com -n 1 -w 5000 > nul
if errorlevel 1 echo Not connected
ping -n 30 127.0.0.1 > nul
goto loop

Answer 5

Here is a script to help you start with it:

http://www.techimo.com/forum/networking-internet/73769-handy-batch-file-check-network-connectivity.html

NOTE: If your system is not in English, you will have to modify the lines in the script where find command is being used to filter Reply from from the ping's output to the corresponding string in the system's language.

Answer 6

@echo off
:loop
ping www.google.com -n 1 -w 5000 >NUL
if errorlevel 1 echo Not connected
goto Loop

Answer 7

echo Testing Internet Connection of google.com
@echo off
:loop
ping google.com -n 1 -w 5000 > nul
if errorlevel 1 echo %date% - %time% Not connected >> pingtestlog.txt
ping -n 30 127.0.0.1 > nul
goto loop

Answer 8

I understand this is an old thread, but here's my contribution anyways.

@echo off

TITLE Network Connection Watchdog

:: Use Windows "Task Scheduler".
:: Set to run at "Startup" with a delay and interval of your choice.
:: Remember to tick "Run with highest privileges".

:: Last command will only be executed if all pings fail.

set /a pc=0
set /a total=0

:: Your preferences
set if="Wi-fi" &:: Find your interface name with [netsh interface show interface].
set ip=192.168.0.1
set /a pt=10 &:: Set amount of pings to be executed.

:loop
set /a pc+=1
ping %ip% -n 1 -w 100 | find "TTL=" >NUL 2>&1
for /f %%a in ('echo %errorlevel%') do set p%pc%=%%a

set /a total+=p%pc%
if not %pc%==%pt% goto loop

if not %total%==%pt% (
goto eof
) else (
netsh interface set interface %if% disable
ping localhost -n 5 >NUL 2>&1
netsh interface set interface %if% enable
)

:eof
exit

Answer 9

This basic script can ping google.com continuously and test your internet connection. script will run in a loop until you close the window.

@echo off
:loop
ping www.google.com -n 1 -w 5000 > null
    if not errorlevel 1 set msg=Your are connected with internet...
    if errorlevel 1 set msg=No Internet...
cls
color 0a
echo %msg%
goto loop