在Clojure中将多个过滤器应用于鹅口疮中的集合

Question

The following code

(let [coll [1 2 3 4 5]
      filters [#(> % 1) #(< % 5)]]
  (->> coll
       (filter (first filters))
       (filter (second filters))))

Gives me

(2 3 4)

Which is great, but how do I apply all the filters in coll without having to explicitly name them?

There may be totally better ways of doing this, but ideally I'd like to know an expression that can replace (filter (first filters)) (filter (second filters)) above.

Thanks!

Answer 1

Clojure 1.3有一个新的every-pred函数，你可以这样使用：

(filter (apply every-pred filters) coll)

Answer 2

This should work :-

(let [coll [1 2 3 4 5]
      filters [#(> % 1) #(< % 5)]]
  (filter (fn [x] (every? #(% x) filters)) coll)
)

Answer 3

I can't say I'm very proud of the following, but at least it works and allows for infinite filters:

(seq 
  (reduce #(clojure.set/intersection 
          (set %1) 
          (set %2)) (map #(filter % coll) filters)))

If you can use sets in place of seqs it would simplify the above code as follows:

(reduce clojure.set/intersection (map #(filter % coll) filters))

Answer 4

(let [coll [1 2 3 4 5]
      filters [#(> % 1) #(< % 5)]]
  (reduce (fn [c f] (filter f c)) coll filters))