将nil分配给TImage.Picture.Graphic以清除图片后，我该如何再次使用它？

Question

In the code below, I clear the Picture in btnSaveClick, later in btnLoadClick I want to assign a picture to the image, but it gives an AV because the Graphic object does not exist.

How can I accomplish the task?

procedure TForm1.btnSaveClick(Sender: TObject);
var
  fs: TFileStream;
  s:  TMemoryStream;
  buf: TBytes;
  z:  integer;
begin
  fs := TFileStream.Create('c:\temp\a.my', fmCreate);
  s  := TMemoryStream.Create;
  try
    Image1.Picture.Graphic.SaveToStream(s);
    z := s.Size;
    SetLength(buf, z);
    s.Position := 0;
    s.ReadBuffer(buf[0], z);

    fs.WriteBuffer(z, SizeOf(integer));
    fs.WriteBuffer(buf[0], z);
  finally
    s.Free;
    fs.Free;
  end;

  ShowMessage('ok');

  Image1.Picture.Graphic := nil;
end;

procedure TForm1.btnLoadClick(Sender: TObject);
var
  fs: TFileStream;
  s:  TMemoryStream;
  buf: TBytes;
  z:  integer;
  gc: TGraphicClass;
begin
  fs := TFileStream.Create('c:\temp\a.my', fmOpenRead);
  s  := TMemoryStream.Create;
  try
    fs.ReadBuffer(z, SizeOf(integer));
    SetLength(buf, z);
    fs.ReadBuffer(buf[0], z);
    s.WriteBuffer(buf[0], z);
    s.Position := 0;

    Image1.Picture.RegisterFileFormat('jpg', 'jpeg files', gc);
  //  Image1.Picture.Graphic.LoadFromStream(s);  <-- AV here. Whats the proper way to do it?

  finally
    s.Free;
    fs.Free;
  end;

  ShowMessage('ok');

end;

Answer 1

If you're loading from a file with an extension which corresponds with a registered image class you can simply do:

Picture.LoadFromFile(FileName);

Otherwise you can create an instance of a specific TGraphic descendant (depending on what type of graphic you're using) in code and assign it to Graphic property, eg for JPEG:

var
  Graphic: TJpegImage;
begin
  Graphic := TJpegImage.Create;
  try
    Graphic.LoadFromFile(FileName);
    Picture.Graphic := Graphic;
  finally
    Graphic.Free;
  end;
end;

Answer 2

Instead doing

Image1.Picture.Graphic := nil;

You could do:

Image1.Visible:= false;

or

Image1.Picture.Assign(HiddenImage2.Picture);

Where HiddenImage2 is a blank TImage.

Answer 3

You have to tell TPicture what TGraphic class to use before you can load data into it. If you only have 1 graphic type you use, then you can hard-code it, eg:

procedure TForm1.btnSaveClick(Sender: TObject);
var
  fs: TFileStream;
  s:  TMemoryStream;
  z:  integer;
begin
  s := TMemoryStream.Create;
  try
    Image1.Picture.Graphic.SaveToStream(s);
    fs := TFileStream.Create('c:\temp\a.my', fmCreate);
    try
      z := s.Size;
      fs.WriteBuffer(z, SizeOf(integer));
      s.Position := 0;
      fs.CopyFrom(s, z);
    finally
      fs.Free;
    end;
  finally
    s.Free;
  end;
  ShowMessage('ok');
  Image1.Picture.Graphic := nil;
end;

procedure TForm1.btnLoadClick(Sender: TObject);
var
  fs: TFileStream;
  s:  TMemoryStream;
  z:  integer;
  jpg: TJPEGImage;
begin
  s := TMemoryStream.Create;
  try
    fs := TFileStream.Create('c:\temp\a.my', fmOpenRead);
    try
      fs.ReadBuffer(z, SizeOf(integer));
      s.CopyFrom(fs, z);
    finally
      fs.Free;
    end;
    jpg := TJPEGImage.Create;
    try
      s.Position := 0;
      jpg.LoadFromStream(s);
      Image1.Picture.Graphic := jpg;
    finally
      jpg.Free;
    end;
  finally
    s.Free;
  end;
  ShowMessage('ok');
end; 

However, If you use multiple graphic types, then you have to store the image type in the file and read it back so you can create the correct class object, eg:

procedure TForm1.btnSaveClick(Sender: TObject);
var
  fs: TFileStream;
  s:  TMemoryStream;
  z:  integer;
  str: AnsiString;
begin
  str := Image1.Picture.Graphic.ClassName;
  s := TMemoryStream.Create;
  try
    Image1.Picture.Graphic.SaveToStream(s);
    fs := TFileStream.Create('c:\temp\a.my', fmCreate);
    try
      z := Length(str);
      fs.WriteBuffer(z, SizeOf(integer));
      fs.WriteBuffer(Str[1], z);
      z := s.Size;
      fs.WriteBuffer(z, SizeOf(integer));
      s.Position := 0;
      fs.CopyFrom(s, z);
    finally
      fs.Free;
    end;
  finally
    s.Free;
  end;
  ShowMessage('ok');
  Image1.Picture.Graphic := nil;
end;

procedure TForm1.btnLoadClick(Sender: TObject);
var
  fs: TFileStream;
  s:  TMemoryStream;
  z:  integer;
  str: AnsiString;
  g:  TGraphic;
begin
  s := TMemoryStream.Create;
  try
    fs := TFileStream.Create('c:\temp\a.my', fmOpenRead);
    try
      fs.ReadBuffer(z, SizeOf(integer));
      SetLength(str, z);
      fs.ReadBuffer(str[1], z);
      fs.ReadBuffer(z, SizeOf(integer));
      s.CopyFrom(fs, z);
    finally
      fs.Free;
    end;
    g := TGraphicClass(FindClass(str)).Create;
    try
      s.Position := 0;
      g.LoadFromStream(s);
      Image1.Picture.Graphic := g;
    finally
      g.Free;
    end;
  finally
    s.Free;
  end;
  ShowMessage('ok');
end;