如何在ActionScript3中将变量从一个瑞士法郎传递到另一瑞士法郎？

Question

I have two swf(a.swf anb b.swf) in as3 . Now I want pass variable From a.swf to b.Swf.i follow this link Tutorial i used the Loader Class.Here my Coding.

var loader:Loader = new Loader();
loader.load("a.swf?test=hi");

But i got Error Message

TypeError: Error #1034: Type Coercion failed: cannot convert "textchat.swf?test=hi" to flash.net.URLRequest. at BasicTickerSprite_fla::MainTimeline/frame1()

How Can i rectify this problem?How Can i pass a String From one Swf to another Swf? Anyone Kindly Explain me in Detail Thaks in Advance

Answer 1

签出flash.net.LocalConnection

Answer 2

ExternalInterface is a good approach.

Perhaps better yet would be the LocalConnection class:

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/net/LocalConnection.html

Maybe a good start to understand basic concepts is from this answer provided here at Stack Overflow:

How to pass a String from a SWF into another SWF

Answered by Plastic Sturgeon:

Let's clarify a bit: 1. The loader swf, we will call the parent. 2. The swf loaded by the parent we will call the child.

The Child contains a string, and you want the parent to be able to read that string> So... The Child must define a public variable for the string. (This means you have to use a Class file for it, since you cannot declare a property public on the timeline.)

Finally, the parent will try and get that property. You may want to wrap that in a try/catch to handle cases where the string will not be present.

Here is an example Child Class.

 package { import flash.display.Sprite; /** * ... * @author Zach Foley */ public class Child extends Sprite { public var value:String = "This is the child Value"; public function Child() { trace("Child Loaded"); } } } 

And here is the parent loader class:

 package { import flash.display.Loader; import flash.display.Sprite; import flash.events.Event; import flash.net.URLRequest; /** * ... * @author Zach Foley */ public class Parent extends Sprite { private var loader:Loader; public function Parent() { trace("PArent Init"); loader = new Loader(); loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded); loader.load(new URLRequest("child.swf")); } private function onLoaded(e:Event):void { trace("Child Loaded"); trace(loader.content['value']); } } } 

The Output will be: PArent Init Child Loaded Child Loaded This is the child Value

Answer 3

var loader:Loader = new Loader();
loader.load(new URLRequest("http//localhost/a.swf?test=hi"));

you'll need a local server for it
update :

    private var _ldr:Loader;
    private var _mc:MovieClip;
    public function Main():void {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init(e:Event = null):void {
        removeEventListener(Event.ADDED_TO_STAGE, init);
        // entry point
        _ldr = new Loader();
        _ldr.contentLoaderInfo.addEventListener(Event.INIT, onInit);
        _ldr.load(new URLRequest('a.swf'));
    }

    private function onInit(e:Event):void{
        _mc = _ldr.content as MovieClip;
        _mc['test'] = 'hi';
        addChild(_mc);
    }

Answer 4

I know this is an old topic but I recently had to reference a smartfox server instance and variables between multiple swfs. I thought i'd share the basics on how i achieved this.

ParentSWF

public var MyVar:String = "Hello";
public var sfs:SmartFox = new SmartFox(true);
private var ChildMC:MovieClip = new MovieClip();
private var myLoader:Loader;

private function LoadChildSWF(evt:Event):void //i used button click event to load swf
    {
    myLoader = new Loader();                     // create a new instance of the Loader class
    var url:URLRequest = new URLRequest("YOURSWF.swf"); // in this case both SWFs are in the same folder
    try
        {
            myLoader.load(url);
            myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE,FFLoaded);

        } 
        catch (error:Error) 
        {
            trace("Unable to load requested document.");
        }
    }
    function FFLoaded(e:Event):void
    {
        ChildMC= myLoader.content as MovieClip;
        addChild(ChildMC);
        ChildMC.init(this);

    }
    public function RemoveChildMC():void
    {
        removeChild(ChildMC);
        ChildMC=null;
    }

ChildSWF

package
{
import com.smartfoxserver.v2.SmartFox;

public class ChildDocumentClass extends MovieClip
{
    private var refDocument:*;
    private var ChildVar:String;
    private var sfs:SmartFox;
    public function ChildDocumentClass()
    {
        trace("Initilise ChildDocumentClass");
        // Nothing to do
    }
    public function init(refDoc:*):void
    {
        // Get the references to the Document Class
        refDocument = refDoc;
        // Get the references to the Server Instance
        sfs=refDocument.sfs;
    //Pass Parent Variable to child variable 
        ChildVar=refDocument.MyVar;
    }
//call to parent class function example to remove loaded swf
    private function UnloadThisSWF():void
    {
        refDocument.RemoveChildMC();
    }
}
}

As you can see communication can be achieved by passing the parent class to the child class through the init(refDoc:*) function.

Answer 5

You can attain better communication between SWFs using ExternalInterface object.

Look at here for adobe reference.

and take a look at following links.

• link1
• link2