在Visual Basic中声明数组大小

Question

This is my first time working with VB. I'm mostly used to working in matlab and am finding that a lot of what I take for granted in matlab must be explicitly declared in VB. Frustrating!

In particular I need to declare two array sizes s1 and s2. As you can see in the code below, s1 is the number of elements in set "n" where the variable "stratum" equals 1. s2 is the number of elements in set "n" where the variable "stratum" equals 2. Pretty straightforward.

My approach is simply to loop the stratum variable 1 through n and count these occurences; and then declare the resulting sums as constants. This would work swimmingly in matlab, but VB is not accepting s1 and s2 as constants. It won't even display s1 and s2 when I insert a debug.print command after the loop.

I have looked through the relevant posts already made. I appreciate any advice. Thanks.

    Sub TOAinput()

    Const n As Integer = 648

    Dim stratum(n), hybrid(n), acres(n), hhsz(n), offinc(n)

    For i = 1 To n
        stratum(i) = Worksheets("hhid level").Cells(i + 1, 2).Value
    Next i

    Dim s1 As Integer
    Dim s2 As Integer


    s1 = 0
    s2 = 0
    For i = 1 To n
        If stratum(i) = 1 Then
            s1 = s1 + 1
        Else:
            s2 = s2 + 1
        End If
    Next i

    Dim acres1(s1), hhsz1(s1), offinc1(s1), acres2(s2), hhsz2(s2), offinc2(s2)

    (...)
    End Sub

Answer 1

A couple of comments:

If you're changing the values of s1 and s2 in your code (as you are in your for loop) they should not be declated as Const. You also appear to be trying to use s1 and s2 before they have been declared.

I'm not sure what exactly you are trying to do with the "Const s1 As Integer = s1" statements. You probaly just want "Dim s1 as Integer" and "Dim s2 as Integer" near the top of your code.

Answer 2

This should work slightly better for you:

Sub TOAinput()

Const n As Integer = 648

Dim stratum(n) As Integer
Dim hybrid(n) As Integer
Dim acres(n) As Integer
Dim hhsz(n) As Integer
Dim offinc(n) As Integer

Dim i As Integer

For i = 1 To n
    stratum(i) = Worksheets("hhid level").Cells(i + 1, 2).Value
Next

Dim s1 As Integer
Dim s2 As Integer

For i = 1 To n
    If stratum(i) = 1 Then
        s1 = s1 + 1
    Else
        s2 = s2 + 1
    End If
Next

Dim acres1() As Integer
Dim hhsz1() As Integer
Dim offinc1() As Integer
Dim acres2() As Integer
Dim hhsz2() As Integer
Dim offinc2() As Integer

ReDim acres1(s1)
ReDim hhsz1(s1)
ReDim offinc1(s1)
ReDim acres2(s2)
ReDim hhsz2(s2)
ReDim offinc2(s2)

(...)
End Sub

I would also recommend that, if possible, you declare the types on the arrays. I have assumed that they are all ints and modified the code appropriately, but this may not work in your situation (ie different data types).