如何计算文本文件Groovy中的匹配块

Question

Say I have a text file that looks like this (including the filename matches part):

filename    matches
bugs.txt    5
bugs.txt    3
bugs.txt    12
fish.txt    4
fish.txt    67
birds.txt    34

etc...

I want to make a new text file, each line of which represents a single filename with the following information: filename, number of times filename appears, sum of matches

so the first three lines would read :

bugs.txt    3    20
fish.txt    2    71
birds.txt   1    34

the first line of the original text file (which contains the text filename /t matches is making things hard for me. Any advice?

Here's my code that doesn't quite do the trick (off by one errors...):

h = null
instances = 0
matches = 0

f.eachLine { line ->

String[] data = line.split (/\t/)

if (line =~ /filename.*/) {}

else {
    source = data[0]  

    if ( source == h) {
        instances ++
        matches = matches + data[9]
    }
    else {
        println h + '\t' + instances + '\t' + matches
        instances = 0   
        matches = 0
        h = source
    }    
} 
}

note: the indices for data[] correspond to the actual text file I'm using

Answer 1

I came up with this (using dummy data)

// In reality, you can get this with:
// def text = new File( 'file.txt' ).text
def text = '''filename\tmatches
             |bugs.txt\t5
             |bugs.txt\t3
             |bugs.txt\t12
             |fish.txt\t4
             |fish.txt\t67
             |birds.txt\t34'''.stripMargin()

text.split( /\n|\r|\n\r|\r\n/ ).                                // split based on newline
     drop(1)*.                                                  // drop the header line
     split( /\t/ ).                                             // then split each of these by tab
     collect { [ it[ 0 ], it[ 1 ] as int ] }.                   // convert the second element to int
     groupBy { it[ 0 ] }.                                       // group into a map by filename
     collect { k, v -> [ k, v.size(), v*.getAt( 1 ).sum() ] }*. // then make a list of file,nfiles,sum
     join( '\t' ).                                              // join each of these into a string separated by tab
     each {                                                     // then print them out
       println it
     }

Obviously though, this loads the whole file into memory in one go...

Answer 2

The main problems with your code are:

• you're using data[9] when the matches are in column 1
• you skip updating instances and matches when source == h
• since you only println when the filename changes, you don't output the results for the last file

Here's a simpler implementation that accumulates the results in a map:

// this will store a map of filename -> list of matches
// e.g. ['bugs.txt': [5, 3, 12], ...]
def fileMatches = [:].withDefault{[]}

new File('file.txt').eachLine { line ->
    // skip the header line
    if (!(line =~ /filename.*/)) {
        def (source, matches) = line.split (/\t/)
        // append number of matches source's list
        fileMatches[source] << (matches as int)
    }
}
fileMatches.each { source, matches ->
    println "$source\t${matches.size()}\t${matches.sum()}"
}