如果需要从多个表单加载依赖报表，如何将参数传递到Access查询的内部WHERE子句？

Question

My question is very similar to this one, and I would have followed up by commenting on the latter but I don't have enough rep yet to comment, so...

What if I want my parameterized report to be able to be loaded by various different forms? Having a reference to a form directly in the query precludes this, does it not? It seems like yucky tight coupling to me.

Is there no way to feed parameters into a query without having the query making reference to a form? (And, like in the linked question above, the relevant WHERE clause in embedded in a nested SELECT, so feeding a WHERE clause into DoCmd doesn't do the trick.)

Answer 1

Look at the FilterName and WhereCondition arguments of the OpenReport method. Alternatively, you could set the report's RecordSource to a SQL string that you build using the report's OpenArgs; when you call OpenReport, you pass the names of the form and of the controls that you want to use for parameters to the OpenArgs parameter, and then you have access to this data through the report's OpenArgs property.

I have a former colleague who assiduously avoided using SQL strings for RecordSource, because "compiled queries are faster". However, I've never found a case where the difference in speed was enough to notice.

Answer 2

what are you coding this in C# ..? 
if so have a Switch statement perhaps to check the form type 
or what ever it is you are passing and 
dynamically build the where clause based on that should not be to difficult

you can still use code to do this assuming you know VB
or create a Macro do utilize the vb script code behind

Answer 3

Here's the solution I've arrived at. It has some flaws but it lets me store my queries in the usual way in Access while at the same time keeping references to specific forms out of my queries:

I've created a module called Param, and it has the following code:

Option Compare Database

Private m_params As Collection

Public Function ParamLookup(paramName As String) As Variant
    If Not m_params Is Nothing Then
        ParamLookup = m_params(paramName)
    End If
End Function


Public Function FeedParamsTo(reportName As String, theParams As Collection)

    Set m_params = theParams

    If Application.CurrentProject.AllReports(reportName).IsLoaded Then
        DoCmd.Close acReport, reportName
    End If

    DoCmd.OpenReport reportName, acViewPreview

End Function

Then in the form that contains my input controls, I have, for example a button with the following click handler:

Private Sub Button_Click()
    Dim params As Collection
    Set params = New Collection
    params.Add Me!AnInputControl, "param1"
    params.Add Me!AnotherInputControl, "param2"

    Param.FeedParamsTo "nameOfSomeReport", params
End Sub

Finally, in the query that the report uses I can refer to the parameters param1 and param2 using the ParamLookup function, like so:

SELECT * FROM someTable WHERE someColumn = ParamLookup("param1") AND someOtherColumn = ParamLookup("param2")

Some drawbacks:

• It's a global module, so there is only one set of parameters able to be read at a time. If you load two reports, the parameters for the first report are overwritten and a refresh of the form may result in weird errors. Of course, it should be possible to extend the idea here to a class and have one instance created per form, but I don't need anything that fancy for the moment.
• If you open the report in Report view without using the button, and hence the FeedParamsTo method, (eg. from the Access Objects panel) then the ParamLookups fail and the report shows up with no records