SQL Server函数始终返回NULL

Question

I'm pulling my hair out here. The function below always returns null, even though it works fine if I pull the code out into a query window and set the input parameters manually. The idea is that I have a different query based on the month, because each month's average value is stored in a different column. I know, the table's not well normalized, but it's what I have to work with. What am I missing?

ALTER FUNCTION [dbo].[fn_currentShareBal]
(
@currentDate    datetime,
@account        integer,
@acctType       varchar
)  
RETURNS money AS  
BEGIN

DECLARE @dte char(10)
DECLARE @returnVal money
DECLARE @month int

SET @dte = CONVERT(char(10), @currentDate, 101)
SET @month = MONTH(@currentDate)

-- because of the table strucure the actual query depends on the month
IF @month = 1 SET @returnVal = (SELECT SUM(avg1)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 2 SET @returnVal = (SELECT SUM(avg2)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 3 SET @returnVal = (SELECT SUM(avg3)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 4 SET @returnVal = (SELECT SUM(avg4)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 5 SET @returnVal = (SELECT SUM(avg5)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 6 SET @returnVal = (SELECT SUM(avg6)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 7 SET @returnVal = (SELECT SUM(avg7)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 8 SET @returnVal = (SELECT SUM(avg8)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 9 SET @returnVal = (SELECT SUM(avg9)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 10 SET @returnVal = (SELECT SUM(avg10)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 11 SET @returnVal = (SELECT SUM(avg11)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

IF @month = 12 SET @returnVal = (SELECT SUM(avg12)
                        FROM COSHAVG
                        WHERE cuID = @account
                        AND avgBalanceMonth =  @dte
                        AND acctType = @acctType)

RETURN @returnVal

END
GO

Answer 1

I think the problem is with your function definition. It's hard to tell as you haven't posted your table's definition.

Does this work? If not, can you post a scripted Create on the COSHAVG table?

ALTER FUNCTION [dbo].[fn_currentShareBal]
(
    @currentDate    datetime,
    @account        integer,
    @acctType       varchar(50)
)  
RETURNS money
AS  
BEGIN
    DECLARE @dte varchar(20)
    DECLARE @returnVal money
    DECLARE @month int

    SET @dte = CONVERT(varchar, @currentDate, 101)
    SET @month = MONTH(@currentDate)

    SELECT
        @returnVal=SUM(CASE
            WHEN @month = 1 THEN avg1
            WHEN @month = 2 THEN avg2
            WHEN @month = 3 THEN avg3
            WHEN @month = 4 THEN avg4
            WHEN @month = 5 THEN avg5
            WHEN @month = 6 THEN avg6
            WHEN @month = 7 THEN avg7
            WHEN @month = 8 THEN avg8
            WHEN @month = 9 THEN avg9
            WHEN @month = 10 THEN avg10
            WHEN @month = 11 THEN avg11
            WHEN @month = 12 THEN avg12
        END)
    FROM COSHAVG
    WHERE cuID = @account
    AND avgBalanceMonth =  @dte
    AND acctType = @acctType

    RETURN @returnVal
END
GO

Answer 2

Others have pointed out things to look for in the comments, but here's a cleaner way to rewrite the function (no real change in behavior, just easier to maintain):

ALTER FUNCTION [dbo].[fn_currentShareBal]
    (
      @currentDate DATETIME
    , @account INTEGER
    , @acctType VARCHAR (100) 
    )
RETURNS MONEY
AS 
    BEGIN
        DECLARE @dte CHAR(10)
        DECLARE @returnVal MONEY
        DECLARE @month INT
        SET @dte = CONVERT(CHAR(10), @currentDate, 101)
        SET @month = MONTH(@currentDate) 
         -- because of the table strucure the actual query depends on the month 

        SELECT  @returnVal = SUM(CASE WHEN @month = 1 THEN avg1
                                      WHEN @month = 2 THEN avg2
                                    /*...*/
                                      WHEN @month = 12 THEN avg12
                                 END)
        FROM    COSHAVG
        WHERE   cuID = @account
                AND avgBalanceMonth = @dte
                AND acctType = @acctType


        RETURN @returnVal
    END