XSL | 通过查找文档排序

Question

gulp First post....

The Situation

I use two XML Files for my XSL Transformation. File1 handles Storage while File2 stores Layout-Information.

<item id="1100326">
   <node1> ... </node1>
   [...]
</item>

 <topnews>
    <item vieworder="1">1100326</item>
    <item vieworder="2">1100724</item>
 </topnews>

I managed to "extract" nodes listed in the layout-XML solely:

<xsl:for-each select="item[@id=document($document)//topnews/item]" />

The Problem

I am having serious trouble sorting the data via the attribute from the layoutXML. I'd appreciate any help and am willing to learn from the masters! :)

Answer 1

+1 for a good first question. This is how I would do it....

data.xml

<doc>
  <item id="1100724">
    <node1>Should be second.</node1>
  </item>
  <item id="1100326">
    <node1>Should be first.</node1>
  </item>
</doc>

layout.xml

<topnews>
  <item vieworder="1">1100326</item>
  <item vieworder="2">1100724</item>
</topnews>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/doc">
    <doc>
      <xsl:apply-templates select="item">
        <xsl:sort select="document('layout.xml')/topnews/item[.=current()/@id]/@vieworder" data-type="number"/>
      </xsl:apply-templates>      
    </doc>
  </xsl:template>

</xsl:stylesheet>

output.xml

<doc>
   <item id="1100326">
      <node1>Should be first.</node1>
   </item>
   <item id="1100724">
      <node1>Should be second.</node1>
   </item>
</doc>

Answer 2

Can you use XSLT 2.0 (as supported by Saxon 9 or AltovaXML)?

With that you could simply do eg

<xsl:variable name="layout-doc" select="document('layout.xml')"/>

<xsl:key name="k1" match="topnews/item" use="."/>

<xsl:template match="/">
  <xsl:for-each select="//item[key('k1', @id, $layout-doc)]">
    <xsl:sort select="xs:integer(key('k1', @id, $layout-doc)/@vieworder)"/>
  </xsl:for-each>
</xsl:template>