XML文件使用XSLT对特定节点进行排序

Question

I am not very good with xsl, but I would like to sort the following xml:

<Parent>
        <node1/>
        <class>b</class>

        <class>c</class>


         <node2/> 
        <class>a</class>
</Parent>

into the following so that only the class elements are sorted and other elements are untouched:

<Parent>
        <node1/>
        <class>a</class>
        <class>b</class>
        <class>c</class>
        <node2/>        
</Parent>

I am using the following xsl within a java code to transform my xml :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
     <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template> 
  <xsl:template match="class">
    <xsl:copy>
    <xsl:apply-templates select="*" >
    <xsl:sort order="ascending" select="class" />

    </xsl:apply-templates>
    </xsl:copy>
    </xsl:template> 
</xsl:stylesheet>

this gives me :

<Parent>
    <node1/>
    <class/>
    <class/>
    <node2/>
    <class/>
</Parent>

Answer 1

Use:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="class[1]">
    <xsl:for-each select="//class">
      <xsl:sort select="."/>
      <xsl:copy-of select="."/>
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="class"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

Output:

<Parent>
  <node1 />
  <class>a</class>
  <class>b</class>
  <class>c</class>
  <node2 />
</Parent>