为XSLT Copy-Of编写模板以转换具有差异的消息。 怎么样？

Question

I have an xml message that is in the older schema (xsd) format. My new schema is exactly the same but I embedded an element inside the older one. For example :

My old schema had an element :

<exclude> MyRestriction </exclude>

but my new schema is like this :

<exclude> <restriction> MyRestriction </restriction> </exclude>

and the entire message is the same as before. Last time I used to do a copy-of but now I need to have a template that copy-of everything but move the value of the exclude to the restriction tag. Anyone can help me please ?

Thanks

Answer 1

You could use a template to match the text in an exclude template

<xsl:template match="exclude/text()">
   <restriction><xsl:value-of select="." /></restriction>
</xsl:template>

This way will keep any other child elements within exclude should they be required.

So, given the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="exclude/text()">
      <restriction><xsl:value-of select="." /></restriction>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

When applied to the following XML

<exclude ex="1"> MyRestriction <test>Hello</test> </exclude>

The following is output

<exclude ex="1">
   <restriction> MyRestriction </restriction>
   <test>Hello</test>
</exclude>

Answer 2

Use this template:

<xsl:template match="exclude">
  <xsl:copy>
    <restriction>
      <xsl:value-of select="."/>
    </restriction>
  </xsl:copy>
</xsl:template>