Perl：匹配数组元素，然后将PREVIOUS（5个索引返回）数组元素复制到新数组

Question

essentially what I'm trying to do is search through a large text file to identify every element that says " no hits found ", and copy that matches identifier to a new list. I am fine with the first part of this, but what I can't seem to figure out is how to then copy the element of the array exactly 5 indices back (which is an identifier) and copy it to a different array.

I tried something like this,

$fastafile = 'HpHcTEST.txt';
open(FASTAFILE, $fastafile);
@seq = <FASTAFILE>;
my $fastaid;
foreach (@seq) {
    if ($_ =~ /\*\*\*\*\* No hits found \*\*\*\*\*/){
        $fastaid .= $_[-5];
    }
}

print "here are the IDs\n";
print $fastaid;

with a tonne of variants of the [-5], but none of them worked.. I can't seem find any documentation on how to back reference and attain a previous element if a match is met. Anyone know how to code for this?

Thank you very much for your time.

Andrew

Answer 1

A quick fix

One way to do it is to walk over @seq with an index.

my @fastaid;

for (my $i = 0; $i < @seq; ++$i) {
    if ($seq[$i] =~ /\*\*\*\*\* No hits found \*\*\*\*\*/){
        push @fastaid, $seq[$i - 5] if $i >= 5;
    }
}

Note the change away from the scalar to an array named @fastaid , which you might print using

print "Here are the IDs:\n";
print "  - $_\n" for @fastaid;

or even

print "Here are the IDs:\n",
      map "  - $_\n", @fastaid;

Adding polish

As brian d foy notes in a comment below, the code could be more elegant and express the intent more directly.

my $id_offset = 5;
my @fastaid;

for ($id_offset .. $#seq) {
    if ($seq[$_] =~ /\*\*\*\*\* No hits found \*\*\*\*\*/){
        push @fastaid, $seq[$_ - $id_offset];
    }
}

As documented in the “Scalar Values” section of perldata , $#seq is the index or of the last element in @seq . The .. range operator correctly handles the case where @seq is fewer than $id_offset elements in length.

The explicit regex-bind operator is still a bit unperlish. You could go with

my $id_offset = 5;
my @fastaid;

for my $i ($id_offset .. $#seq) {
  for ($seq[$i]) {
    push @fastaid, $seq[$i - $id_offset]
      if /\*\*\*\*\* No hits found \*\*\*\*\*/;
  }
}

or if you have at least version 5.10

use feature 'switch';

# ...

my $id_offset = 5;
my @fastaid;

for my $i ($id_offset .. $#seq) {
  given ($seq[$i]) {
    when (/\*\*\*\*\* No hits found \*\*\*\*\*/) {
      push @fastaid, $seq[$i - $id_offset];
    }
  }
}

Historical note

Back in the day, there was some talk of repurposing $# to track the index of an array traversal so you could have written

for (@fastaid) {
    if (/\*\*\*\*\* No hits found \*\*\*\*\*/) {
        push @fastaid, $seq[$# - 5] if $# >= 5;
    }
}

but that never materialized.

Answer 2

You can iterate over the indices and subscript to get the array elements:

for (5..$#seq) {
    $fastaid .= $seq[$_-5] if $seq[$_] =~ /your_regex/;
}

In Perl 5.12 or better you can also use each :

while (my ($index, $value) = each @seq) {
    next if $index < 5;
    $fastaid .= $seq[$index-5] if $value =~ /your_regex/;
}

Answer 3

my @fasta_id = map { $seq[$_] =~ /your_regex/ ? $seq[$_-5] : () } 5 .. $#seq;

Answer 4

Use a 'for' loop instead of 'foreach',

for ($index=0; $index < $#seq + 1; $index++) {
    if ($seq[$index] =~ /\*\*\*\*\* No hits found \*\*\*\*\*/){
        $fastaid .= $seq[$index-5];
    }
}