如何通过转换退出下载数据？

Question

I try to download an internal table to my PC and the download should use the conversion exits.

An example: Table T002 contains a language key with one character (T0002-SPRAS).

When I WRITE T0002-SPRAS. the conversion routine ISOLA is used and I get a two character language key ( E becomes EN ...) This conversion routine should be used for my export.

My test report:

REPORT  Y_MY_DOWNLOAD_TEST.

CONSTANTS: c_filename type string VALUE 'C:\temp\test.txt'.
data: it_table type table of t002.

start-of-selection.

  SELECT * from t002 into table it_table.

* Start file download
  CALL METHOD cl_gui_frontend_services=>gui_download
    EXPORTING
      filename                  = c_filename
      filetype                  = 'ASC' "or DAT
      WRITE_FIELD_SEPARATOR     = 'X'
      WRITE_LF                  = 'X'
*      DAT_MODE                  = SPACE
      codepage                  = '4110'        "UNICODE
      SHOW_TRANSFER_STATUS      = 'X'
      WRITE_LF_AFTER_LAST_LINE  = 'X'
    CHANGING
      data_tab                  = it_table
    EXCEPTIONS
      OTHERS                    = 99.

  write: 'end'.

The result is a file without the usage of the conversion exit (English keeps E ).

The SAP documentation mention the parameter dat_mode :

If this flag is set, .... Conversion exits are not executed.

I don't set the flag,so I would expect, the conversions are done. I tried different combinations ( dat_mode on/off, filetype ASC and DAT), but I found never a conversion.

Remarks:

• I use SAP Release 7.01, Support Package SAPKB70107. It is a unicode system.
• T002 is only an example, my real data are other data, containing language key.

I'm looking for a solution with gui_download (or another standard method/function module).

I don't want to build my own export file like this:

data: 
  tmp type string,
  targetline type string,
  targettable type table of string.
loop at it_table into sourceline.
  "This could be done dynamic with field symbols and ASSIGN COMPONENT
  write sourceline-field1 to tmp. 
  CONCATENATE targetline ';' tmp into targetline.
  "...
  APPEND targetline to targettable.
endloop.

This will be a possible solution, but in this case it would be easier for me to adapt the consumer of the export file.

Answer 1

I don't think it's possible. You could however join the LAISO value (which is the value the SPRAS output conversion function returns) in your queries which include an SPRAS type of field, and use a custom type for the query in which you replace the SPRAS type field with the LAISO type.
Here's an example using the T003P table:

types: begin of ty_t003p,
         client type mandt,
         spras type laiso,
         auart type aufart,
         txt type auarttext,
       end of ty_t003p.

data ta_t003p type standard table of ty_t003p.

select t003p~client t002~laiso t003p~auart t003p~txt into table ta_t003p from t003p inner join t002 on t002~spras = t003p~spras.

cl_gui_frontend_services=>gui_download(
  exporting
    filename = 'C:\temp\test.txt'
    filetype = 'DAT'
  changing
    data_tab = ta_t003p ).

Answer 2

Okay,

here goes, use SE11, go to the table, double click the data element with the conversion routine to display the data element. Then double click the domain to display the domain then double click the convers. routine name. ( ISOLA in this case ) Since you want the output value ( the input value is in the db ) you want to execute CONVERSION_EXIT_ISOLA_INPUT on the spras field for each table entry.

Something like

data: wa_table type t002.

loop at it_table into wa_table.
CALL FUNCTION 'CONVERSION_EXIT_ISOLA_OUTPUT'
  EXPORTING
    input         = wa_table-spras
 IMPORTING
    OUTPUT        = wa_table-spras.

modify it_table from wa_table index sy-tabix.

endloop.

At this point you can just continue using cl_gui_frontend_services=>gui_download on it_table.

I realize this is close to using your WRITE statement, except that the WRITE statement would get you in trouble.

What we have done at my work is write a program that uses the data dictionary to generate an upload download program.

Table DD04L contains the conversion exit for each table field, and then we do something likes this :

  CONCATENATE 'wa_db-' wa_field-fieldname INTO g_string.

  SELECT SINGLE * FROM dd03l INTO wa_dd03l WHERE tabname EQ p_tab AND fieldname EQ wa_field-fieldname.
  SELECT SINGLE * FROM dd04l INTO wa_dd04l WHERE rollname EQ wa_dd03l-rollname.

  IF wa_dd04l-lowercase IS INITIAL.
    _repl 'translate wa_field to upper case.' g_string.
  ENDIF.
  _add 'if g_oops is initial.'.
  IF wa_dd04l-convexit IS NOT INITIAL.

    _add  'try.'.
    _repl 'move wa_field to &.' g_string.
    _add  'CATCH CX_DYNAMIC_CHECK into gcl_dynamic_check.'.
    _add  'l_error = gcl_dynamic_check->get_text( ).'.
    _add  'l_long_error = gcl_dynamic_check->GET_LONGTEXT( ).'.
    _repl 'concatenate ''Conversion error'' wa_field ''into & ->'' l_error into l_error separated by space.' g_string.
    _add  'condense l_error.' .
    _add  'write l_error. new-line.' .
    _add  'write l_long_error. new-line.' .
    _add  'ENDTRY.'.


    CONCATENATE 'CONVERSION_EXIT_' wa_dd04l-convexit '_INPUT' INTO g_fm.

    _repl '    CALL FUNCTION ''&''' g_fm.
    _add  '      EXPORTING'.
    _repl '        input             = &' g_string.
    _add  '      IMPORTING'.
    _repl '        output            = &' g_string.
    _add  '     EXCEPTIONS'.
    _add  '       length_error       = 1'.
    _add  '       OTHERS             = 2.'.

    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.

with some defines which add code to the generated ABAP

DEFINE _repl.
  wa_prog = &1.
  replace all occurrences of '&' in wa_prog with &2.
  append wa_prog to it_prog.
END-OF-DEFINITION.

DEFINE _add.
  append &1 to it_prog.
END-OF-DEFINITION.

It's a ton of fun to write..

Answer 3

As of ABAP 7.52, I have verified that the conversion exits are executed only when:

• The parameters are either filetype = 'DAT'

  • or filetype = 'ASC' and dat_mode = 'X'

    (not really what the documentation says)

• And only for fields whose data types are 'N', 'D', 'F' (except value 0) or 'T' (but not 'C' which is the most frequent case, especially concerning the conversion exits ALPHA , ISOLA and CUNIT )

  (you may verify these rules on data types in the subroutine Put_Char_LineBuffer of the function group SFES , and more specifically in the subroutine ConvertAsc )

Note that the documentation embedded in the method gui_download of cl_gui_frontend_services says:

DAT mode: No longer supported. Use ASC instead.

So you cannot rely on the conversions done by the method.