从erlang流程获取响应

Question

I have an erlang project that makes a lot of concurrent SOAP requests to my application. Currently, it's limited by how many nodes are available, but I would like to adjust it so that each node can send more than one message at a time.

I've figured that problem out, but I don't know how to get a response back from process running the SOAP request.

This is my function that I'm attempting to use to do multiple threads:

batch(Url, Message, BatchSize) ->
    inets:start(),

    Threads = for(1, BatchSize, fun() -> spawn(fun() -> attack_thread() end) end),
    lists:map(fun(Pid) -> Pid ! {Url, Message, self()} end, Threads).

This function gets called by the person who initiated the stress tester, it is called on every node in our network. It's called continually until all the requested number of SOAP requests have been sent and timed.

This is the attack_thread that is sent the message by the batch method:

attack_thread() ->
 receive
    {Url, Message, FromPID} ->
        {TimeTaken, {ok, {{_, 200, _}, _, _}}} = timer:tc(httpc, request, [post, {Url, [{"connection", "close"}, {"charset", "utf-8"}], "text/xml", Message}, [], []]),
        TimeTaken/1000/1000.
 end

As you can see, I want it to return the number of seconds the SOAP request took. However, erlang's message passing ( Pid ! Message ) doesn't return anything useful.

How can I get a result back?

Answer 1

Each of your attack_thread() threads can simply drop a message in the mailbox of the process operating the batch/3 function:

 FromPid ! {time_taken, self(), TimeTaken / 1000 / 1000}.

but then you need to collect the results:

 batch(Url, Message, BatchSize) ->
  inets:start(),

  Pids = [spawn_link(fun attack_thread/0) || _ <- lists:seq(1, BatchSize],
  [Pid ! {Url, Message, self()} || Pid <- Pids],
  collect(Pids).

 collect([]) -> [];
 collect(Pids) ->
   receive
     {time_taken, P, Time} ->
       [Time | collect(Pids -- [P])]
   end.

Some other comments: you probably want spawn_link/1 here. If something dies along the way, you want the whole thing to die. Also, be sure to tune inets httpc a bit so it is more effective. You might also want to look at basho_bench or tsung.

Finally, you can use a closure directly rather than pass the url and message:

 attack_thread(Url, Message, From) -> ...

So your spawn is:

 Self = self(),
 Pids = [spawn_link(fun() -> attack_thread(Url, Message, Self) end) || _ <- ...]

It avoids passing in the message in the beginning.