将文件移动到另一个文件夹，包括文件名中的创建日期

Question

I am able to move files from one folder to another but the issue is I want the new created file in the new folder as its created date and filename.

For instance

/scripts/a.log

moved to

/log/8june2012a.log

Answer 1

cp filename "`date +%Y%m%d`filename"

This copies filename as 20120608filename . For your example this is what you want:

cp filename "`date +%d%b%Y`filename"

This copies filename as 08jun2012filename . If you want move your file instead of copying use mv instead of cp :

mv filename "`date +%d%b%Y`filename"

Answer 2

Using a couple of CPAN modules this can be made straightforward. File::Copy has been a core module since Perl v5.0, but Date::Format and Path::Class will need installing unless you already have them.

I have taken your requirement literally, and this solution prefixes the original file with the creation date using %e%B%Y as the format, with upper case translated to lower case and spaces stripped. However this isn't very readable and the directory listing will not automatically sort in date order, so I recommend using %Y-%m-%d- instead by replacing the line containing the call to strftime with

my $date = lc strftime('%Y-%m-%d-', @date)

At present the code just prints a list of the files it is going to move and their destination. To actually do the move you should uncomment the call to move .

use strict;
use warnings;

use Path::Class 'dir';
use Date::Format 'strftime';
use File::Copy 'move';

my $source  = dir '/scripts/';
my $dest = dir '/log/';

for my $file (grep { not $_->is_dir } $source->children) {

  my @date = localtime $file->stat->ctime;
  (my $date = lc strftime('%e%B%Y', @date)) =~ tr/\x20//d;

  my $newfile = $dest->file($date.$file->basename);

  print "move $file -> $newfile\n";
  #  move $file, $newfile;
}

Answer 3

Here is a solution in Perl.

#!/usr/bin/perl

use strict;
use warnings;
use File::Copy 'move';
use Time::Piece 'localtime';

my $indir = '/scripts';
my $outdir = '/log';

# get all of the files in the scripts dir
chdir $indir;
my @files = grep -f, glob '*';

foreach my $infile (@files) {
    # get the date that the file was created
    my $file_created_date = localtime( (stat $infile)[9] );
    my $outfile = $file_created_date->strftime('%d%B%Y').$infile;
    move $infile, "$outdir/$outfile";
}

As an aside, I would format the date as %Y%m%d (yyyymmdd) as it gives you a consistent format and allows you to sort by date more easily.

Answer 4

Another solution.

use strict ;
use File::stat ;
use POSIX qw(strftime);

my $File = 'mv.pl';
my $NewFile=strftime("%d%B%Y",localtime(stat($File)->ctime)) . $File ;

rename $File, $NewFile;

Answer 5

use File::Copy;
move("a.log",$DIRECTORY.get_timestamp().".log");

Your get_timestamp function should generate the date.

Answer 6

I wrote a demo for you,

#!/bin/bash

DATE=`date +"%e%B%Y" | tr -d ' ' | tr A-Z a-z`


for FILENAME in *.log
do
        cp "${FILENAME}" "/log/${DATE}${FILENAME}"
done

you can run this in your "scripts" directory.