在Perl中第n个字符的位置/索引处分割字符串（或正则表达式匹配项）？

Question

There is a similarly worded question, but I think this is slightly different.

Basically, say I have this string:

" aa{bb{dccd "

Here I would like to split the string at the last brace { ; and have the parts returned as an array. I can easily find the position (0-based index) of this character using rindex :

perl -e '
$aa="aa{bb{dccd" ;
$ri = rindex($aa, "{") ;
print "$ri\n"; '

5

... and given that I'm not a Perl coder, first thing I think of is to use something like $str = split($aa, 3) . Unfortunately, that is not correct syntax - split takes a regex as first argument (what to match for), and string as second - and it doesn't take an integer position index as argument.

I found posts like Perl Guru Forums: Perl Programming Help: Intermediate: split or splice string on char count? , which recommend using substr in a similar context; however, I'd have to write two substr s to populate the list as per the example above, and so I'd rather hear about alternatives to substr.

Basically, if the problem of matching the position of N-th character can be expressed as a regex match, the split could work just as well - so that would be my primary question. However, I'd also be interested in hearing if there are Perl built-in functions that could accept a list/array of integers specifying character positions, and return an array containing the split sections.

EDIT:

To summarize the above - I'd like to have the character indexes, because I'd like to print them out for debugging; and at the same time, use them for splitting a string into array - but without using substr s.

EDIT2: I just realized that I left something out from the OP -- and that is, that in the problem that I'm working on, I have to first retrieve character indexes (by rindex or otherwise); then I have to do calculations on them (so they may increase, or decrease) - and only then am I supposed to split the string (based on the new index values). It may have been that my original example was too simple, and didn't express this focus on indexes/character positions much ( and not to mention that my first thought of split implies character indexes anyways - but I really cannot remember which programming language it came from :) )

Answer 1

my ($pre, $post) = split /\{(?!.*\{)/s, $s;

or

my ($pre, $post) = $s =~ /^(.*)\{(.*)/s;

The second is probably better.

If you need the index of the { , use length($pre) . (With the second solution, you could also use $-[2] - 1 . See @- and @+ in perlvar .)

Answer 2

You wrote:

I'd also be interested in hearing if there are Perl built-in functions that could accept a list/array of integers specifying character positions, and return an array containing the split sections.

To create a function that takes a list of offsets and produces a list of substrings with those split positions, convert the offsets to lengths and pass these as an argument to unpack .

There's a &cut2fmt function in Chapter 1 of the Perl Cookbook that does this very thing. Here is an excerpt, reproduced here by kind permission of the author:

Sometimes you prefer to think of your data as being cut up at specific columns. For example, you might want to place cuts right before positions 8, 14, 20, 26, and 30. Those are the column numbers where each field begins. Although you could calculate that the proper unpack format is "A7 A6 A6 A6 A4 A*" , this is too much mental strain for the virtuously lazy Perl programmer. Let Perl figure it out for you. Use the cut2fmt function below:

sub cut2fmt {
      my(@positions) = @_;
      my $template   = '';
      my $lastpos    = 1;
      foreach $place (@positions) {
          $template .= "A" . ($place - $lastpos) . " ";
          $lastpos   = $place;
      }
      $template .= "A*";
      return $template;
  }

  $fmt = cut2fmt(8, 14, 20, 26, 30);
  print "$fmt\n";

  A7 A6 A6 A6 A4 A*

So the way you would use that is like this:

$fmt = cut2fmt(8, 14, 20, 26, 30);
@list = unpack($fmt, $string);

or directly as

@list = unpack(cut2fmt(8, 14, 20, 26, 30), $string);

I believe this is what you were asking for.

Answer 3

Here are some ways:

split /.*\K{/, $str;
split /{(?!.*{)/, $str;
$str =~ /(.*){(.*)/;

Use /regex/s if the string can span multiple lines.

Answer 4

The way to do this using rindex is to employ substr to extract the two parts of the string according to the position of the { .

Note that this includes the { in the suffix part. To exclude it you would use $i + 1 in the second substr call.

my $str = "aa{bb{dccd";

my $i = rindex $str, '{';
my $pref = substr $str, 0, $i;
my $suff = substr $str, $i;

print $pref, "\n";
print $suff, "\n";

output

aa{bb
{dccd

---

Update

I have just read about your wish to avoid substr and do the split in a single operation. unpack will do that for you, like this

my $str = "aa{bb{dccd";

my $i = rindex $str, '{';

my ($pref, $suff) = unpack "A$i A*", $str;

print $pref, "\n";
print $suff, "\n";

with identical output to the previous code.

Answer 5

I still don't see what's so difficult about this. Is it that you don't want to discard the brace (or whatever your delimiter is)? These adaptations of @Qtax's solutions leave the brace in either the first or second substring:

# split before the brace
split /.*\K(?=\{)/, $str;
split /(?=\{(?!.*\{))/, $str;
$str =~ /(.*)(\{.*)/;

# split after the brace
split /.*\{\K)/, $str;
split /(?<=\{(?!.*\{))/, $str;
$str =~ /(.*\{)(.*)/;

(I know it isn't necessary to escape the brace, but I think it's a little easier to read this way.)

Answer 6

Right, I'll post this as an answer, this is how far I got.

Thanks to these resources:

• Splitting a string in Perl
• Regular Expressions - a Simple User Guide and Tutorial

... I learned about the "curly brace" regex operator, {n} which ' Matches the preceding character, or character range, n times exactly '. Thus, I can match for /.{5}(.)/ :

perl -e '
$aa="aa{bb{dccd" ;
$aa =~ /.{5}(.)/  && print "--${1}--\n"; '

--{--

this selects through first 5 "any" characters - and then select and print the next one. Or:

/               # start regex
 {              # match "{" character
  {5}           # repeat previous five times
     (.)        # select into match group (the $1) next character
        /       # end regex

So, finally, I can use the rindex to perform such a split:

perl -e '
$aa="aa{bb{dccd" ;
$ri = rindex($aa, "{") ;
$aa =~ /.{$ri}(.)/  && print "--${1}--\n";
@res = split(/^.{$ri}(.)/, $aa);
print join("; ", @res) . "\n"; '

--{--
; {; dccd

.. but given that also requires some capturing at start, so here are other variants:

@res = split(/^(.{$ri})(.)/, $aa);

--{--
; aa{bb; {; dccd


@res = split(/^(.{$ri})./, $aa);

--{--
; aa{bb; dccd

... which both would work for me - except I have a blank as first item, which I'd like to get rid of in one pass (without calling extra splice ), but don't know how to :)

Cheers!