XSLT空格分隔并添加元素

Question

I have a query in the xml and xslt

The below is the Input XML

<?xml version="1.0" encoding="UTF-8"?>    
<Employer>
    <Employees>
        <EmployeesDetails>van ind 26%</EmployeesDetails>
    </Employees>    
    <Employees>
        <EmployeesDetails>van ind</EmployeesDetails>
    </Employees>    
</Employer>

The above is my input file

the below is my output file

<?xml version="1.0" encoding="UTF-8"?>
<Employer>
    <Employees>
        <Names>van</Names>
        <Location>ind</Location>                
        <Weather>26</Weather>
    </Employees>
    <Employees>
        <Names>van</Names>
        <Location>ind</Location>
        <Weather>100</Weather>
    </Employees>
</Employer>

How can I apply the below XSLT to the above XML input?

Answer 1

I. This XSLT 2.0 transformation:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 exclude-result-prefixes="xs">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <Employer>
    <xsl:apply-templates/>
  </Employer>
 </xsl:template>

 <xsl:template match="Employees">
  <xsl:variable name="vNames" select="tokenize(Names, ' ')"/>
  <xsl:variable name="vLoc" select="tokenize(Location, ' ')"/>
  <xsl:variable name="vWeather"
       select="tokenize(translate(Weather, '%', ' '), ' ')"/>
  <xsl:for-each select="$vNames">
    <xsl:variable name="vPos" select="position()" as="xs:integer"/>
    <Employees>
      <Names><xsl:sequence select="."/></Names>
      <Location>
        <xsl:sequence select="(lower-case($vLoc[$vPos]), 'Unknown')[1]"/>
      </Location>
      <Weather>
        <xsl:sequence select="($vWeather[$vPos], 100)[1]"/>
      </Weather>
    </Employees>
    </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<Employer>
    <Employees>
        <Names>vel bel sel tel mel</Names>
        <Location>IND AUS ENG CAL JAP</Location>
        <Weather>26%</Weather>
    </Employees>
    <Employees>
        <Names>asd sadl asdsel tdddel dmdel</Names>
        <Location>IND AUS ENG CAL JAP</Location>
    </Employees>
</Employer>

produces the wanted, correct result:

<Employer>
   <Employees>
      <Names>vel</Names>
      <Location>ind</Location>
      <Weather>26</Weather>
   </Employees>
   <Employees>
      <Names>bel</Names>
      <Location>aus</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>sel</Names>
      <Location>eng</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>tel</Names>
      <Location>cal</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>mel</Names>
      <Location>jap</Location>
      <Weather>100</Weather>
   </Employees>
      <Employees>
      <Names>asd</Names>
      <Location>ind</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>sadl</Names>
      <Location>aus</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>asdsel</Names>
      <Location>eng</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>tdddel</Names>
      <Location>cal</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>dmdel</Names>
      <Location>jap</Location>
      <Weather>100</Weather>
   </Employees>
</Employer>

Do note :

I have made the following reasonable assumptions:

1. You actually want 100 , not 100% .

2. You want all Employees processed -- not only the first occurence of this element.

I also added a default value for any missing location, in case the number of provided locations is less than the number of the provided names.

---

II. XSLT 1.0 solution :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 xmlns:my="my:my" exclude-result-prefixes="ext my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <my:defaults>
  <L>Unknown</L>
  <W>100</W>
 </my:defaults>

 <xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
 <xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:variable name="vDefaults" select="document('')/*/my:defaults"/>

 <xsl:template match="/*">
  <Employer>
   <xsl:apply-templates/>
  </Employer>
 </xsl:template>

 <xsl:template match="Employees">
  <xsl:variable name="vrtfNames">
   <xsl:apply-templates select="Names"/>
  </xsl:variable>
  <xsl:variable name="vNames" select="ext:node-set($vrtfNames)/*"/>
  <xsl:variable name="vrtfLocs">
   <xsl:apply-templates select="Location"/>
  </xsl:variable>
  <xsl:variable name="vrtfWeather">
   <xsl:apply-templates select="Weather"/>
  </xsl:variable>

  <xsl:apply-templates select="$vNames">
   <xsl:with-param name="pLocs" select="ext:node-set($vrtfLocs)/*"/>
   <xsl:with-param name="pWeather" select="ext:node-set($vrtfWeather)/*"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="s" priority="3">
  <xsl:param name="pLocs"/>
  <xsl:param name="pWeather"/>

  <xsl:variable name="vPos" select="position()"/>
  <Employees>
   <Names><xsl:value-of select="."/></Names>
   <Location>
     <xsl:value-of select=
       "translate($pLocs[position() = $vPos]
                   | $vDefaults[not($pLocs[position() = $vPos])]/L,
                  $vUpper, $vLower)"/>
   </Location>
   <Weather>
     <xsl:value-of select=
       "$pWeather[position() = $vPos]
      | $vDefaults[not($pWeather[position() = $vPos])]/W"/>
   </Weather>
  </Employees>
 </xsl:template>

 <xsl:template match="Weather">
  <xsl:call-template name="tokenize">
    <xsl:with-param name="pText" select="translate(., '%', ' ')"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template match="Employees/*/text()" name="tokenize">
  <xsl:param name="pText" select="."/>

  <xsl:variable name="vText" select="normalize-space($pText)"/>
  <xsl:if test="$vText">
   <s>
    <xsl:value-of select="substring-before(concat($vText, ' '), ' ')"/>
   </s>

   <xsl:call-template name="tokenize">
    <xsl:with-param name="pText" select="substring-after($vText, ' ')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document (above), again the same wanted, correct result is produced :

<Employer>
   <Employees>
      <Names>vel</Names>
      <Location>ind</Location>
      <Weather>26</Weather>
   </Employees>
   <Employees>
      <Names>bel</Names>
      <Location>aus</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>sel</Names>
      <Location>eng</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>tel</Names>
      <Location>cal</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>mel</Names>
      <Location>jap</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>asd</Names>
      <Location>ind</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>sadl</Names>
      <Location>aus</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>asdsel</Names>
      <Location>eng</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>tdddel</Names>
      <Location>cal</Location>
      <Weather>100</Weather>
   </Employees>
   <Employees>
      <Names>dmdel</Names>
      <Location>jap</Location>
      <Weather>100</Weather>
   </Employees>
</Employer>

Do note :

1. Essentially the same logic as in the XSLT 2.0 transformation is implemented.

2. As XPath 1.0 doesn't have a tokenize or lower-case() functions and there are is no notion of sequence in the XPath 1.0 data model, these are implemented (respectively) using a template for tokenization, using the translate() function to convert to lower case, and using an element that contains the defaults for weather and location.

Answer 2

Your question is vague in some key areas. For instance, you seem to state that if a <Employees> nodeset doesn't have a <weather> node, it should get one with a value of 100%; that said, your expected output seems to apply that logic inconsistently. Your desired <Location> result node is transformed from uppercase to lowercase. Additionally, your output seems to completely disregard the second <Employees> node-set from the source XML.

Making some assumptions, here is an XSLT 1.0 solution that uses EXSLT . Should this not be what you want, please update your question to be more specific and I will try to accommodate.

When this XSLT:

<?xml version="1.0"?>
<xsl:stylesheet
  xmlns:exsl="http://exslt.org/common"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  exclude-result-prefixes="exsl" 
  version="1.0">

  <xsl:output omit-xml-declaration="no" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Employees">
    <xsl:variable name="vNames">
      <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="Names/text()"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="vLocations">
      <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="Location/text()"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:apply-templates select="exsl:node-set($vNames)/token">
      <xsl:with-param name="pLocation"
          select="exsl:node-set($vLocations)/token"/>
      <xsl:with-param name="pWeather" select="Weather"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="token">
    <xsl:param name="pLocation"/>
    <xsl:param name="pWeather"/>
    <xsl:variable name="vPosition" select="position()"/>
    <Employees>
      <Names>
        <xsl:value-of select="."/>
      </Names>
      <Location>
        <xsl:value-of select="translate($pLocation[$vPosition],
            'ABCDEFGHIJKLMNOPQRSTUVWXYZ', 'abcdefghijklmnopqrstuvwxyz')"/>
      </Location>
      <xsl:choose>
        <xsl:when test="$pWeather != ''">
          <xsl:apply-templates select="$pWeather"/>
        </xsl:when>
        <xsl:otherwise>
          <Weather>100%</Weather>
        </xsl:otherwise>
      </xsl:choose>
    </Employees>
  </xsl:template>

  <xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="' '"/>
    <xsl:choose>
      <xsl:when test="contains($text,$delimiter)">
        <xsl:element name="token">
          <xsl:value-of select="substring-before($text,$delimiter)"/>
        </xsl:element>
        <xsl:call-template name="tokenize">
          <xsl:with-param name="text"
              select="substring-after($text,$delimiter)"/>
          <xsl:with-param name="delimiter" select="$delimiter"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:when test="$text">
        <xsl:element name="token">
          <xsl:value-of select="$text"/>
        </xsl:element>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

...is applied to this XML:

<?xml version="1.0"?>
<Employer>
  <Employees>
    <Names>vel bel sel tel mel</Names>
    <Location>IND AUS ENG CAL JAP</Location>
    <Weather>26%</Weather>
  </Employees>
  <Employees>
    <Names>asd sadl asdsel tdddel dmdel</Names>
    <Location>IND AUS ENG CAL JAP</Location>
  </Employees>
</Employer>

...the desired (?) result is produced:

<?xml version="1.0" encoding="UTF-8"?>
<Employer>
  <Employees>
    <Names>vel</Names>
    <Location>ind</Location>
    <Weather>26%</Weather>
  </Employees>
  <Employees>
    <Names>bel</Names>
    <Location>aus</Location>
    <Weather>26%</Weather>
  </Employees>
  <Employees>
    <Names>sel</Names>
    <Location>eng</Location>
    <Weather>26%</Weather>
  </Employees>
  <Employees>
    <Names>tel</Names>
    <Location>cal</Location>
    <Weather>26%</Weather>
  </Employees>
  <Employees>
    <Names>mel</Names>
    <Location>jap</Location>
    <Weather>26%</Weather>
  </Employees>
  <Employees>
    <Names>asd</Names>
    <Location>ind</Location>
    <Weather>100%</Weather>
  </Employees>
  <Employees>
    <Names>sadl</Names>
    <Location>aus</Location>
    <Weather>100%</Weather>
  </Employees>
  <Employees>
    <Names>asdsel</Names>
    <Location>eng</Location>
    <Weather>100%</Weather>
  </Employees>
  <Employees>
    <Names>tdddel</Names>
    <Location>cal</Location>
    <Weather>100%</Weather>
  </Employees>
  <Employees>
    <Names>dmdel</Names>
    <Location>jap</Location>
    <Weather>100%</Weather>
  </Employees>
</Employer>

Explanation:

1. The first template - the Identity Template - copies all elements and attributes as-is.
2. A second template, which matches <Employee> elements, runs a special tokenize template whose job it is to split your space-separate strings into result tree fragments. These fragments are saved into variables for convenience.
3. A third template matches all elements named token . These are produced by EXSLT, which converts result tree fragments into node-sets comprised of <token> elements. For each one of these, we pull the necessary element values to create <Names> and <Location> . This template also contains the logic necessary to determine which value is required for the <weather> element.