基于同一工作簿中另一个工作表的数据的工作表中的颜色单元格

Question

I have the following worksheet called Data :

In the same workbook I have another worksheet called Employee Database .

In Excel, how can I color the "Employee E-mail Address" and the corresponding "Company" and "Company URL" cells red from the Data worksheet if the "Employee E-mail Address" is not in the Employee Database ?

In otherwords, I am trying to make the Employee Database worksheet look like this:

I've just given an example and in reality I have over 10,000 cells worth of data to do this to. I started doing this manually and realized it will take me forever.

I'd love to know if there is a macro that can do this in Excel?

Help would be so much appreciated! I have the example workbook of the screenshots above available for download here: http://www.mediafire.com/?dttztp66dvjkzn8

Answer 1

Is this what you are trying? This will create a new sheet "Desired Result" with the output. Paste this in a module.

Option Explicit

Sub Sample()
    Dim wsData As Worksheet, wsDB As Worksheet, wsO As Worksheet
    Dim lRow As Long, i As Long
    Dim clrRng As Range

    Set wsData = Sheets("Data")
    Set wsDB = Sheets("Employee Database")
    Set wsO = Sheets.Add

    On Error Resume Next
    Application.DisplayAlerts = False
    Sheets("Desired Result").Delete
    Application.DisplayAlerts = True
    On Error GoTo 0

    With wsO
        .Name = "Desired Result"
        wsData.Cells.Copy .Cells

        lRow = .Range("B" & .Rows.Count).End(xlUp).Row

        For i = 2 To lRow
            If .Range("A" & i).Value = "" Then .Range("A" & i).Value = .Range("A" & i - 1).Value
        Next i

        For i = 1 To lRow
            If Application.WorksheetFunction.CountIf(wsDB.Columns(3), .Range("A" & i).Value) = 0 Then
                If clrRng Is Nothing Then
                    Set clrRng = .Rows(i)
                Else
                    Set clrRng = Union(clrRng, .Rows(i))
                End If
            End If
        Next i

        If Not clrRng Is Nothing Then clrRng.Interior.ColorIndex = 3

        For i = lRow To 2 Step -1
            If .Range("A" & i).Value = .Range("A" & i - 1).Value Then .Range("A" & i).ClearContents
        Next i
    End With
End Sub

Answer 2

You can do this without VBA, but it will require a slight change to the data on your Data sheet.

I don't recommend the "Pivot Table" or "Subtotal"-style of data storage in Excel, where you enter a primary key in one column only once then fill down associated data next to it until the next primary key.

Like merged cells, this will only lead to problems later when you want to re-organize your data.

Here's what I did:

Fill in missing email addresses on Data sheet

Highlight cells A2 all the way down column A to the end of the data in column B . So if you had company names in cells B2:B100 , but only had emails from A2:A98 , you should highlight A2:A100 . This is because we are filling in the email address in each row of available data.

Go to Editing » Find & Select » Go To Special , select Blanks and click OK .

Now with blanks selected, type = ↑ (up arrow) , then press Ctrl + Enter . The blank cells in column A will fill in with the missing email addresses. Highlight column A, copy and paste values.

Create Dynamic Named Range for Emails

On the Employee Database sheet, create a named range called "Emails" with the following formula in the "Refers to" box:

=OFFSET('Employee Database'!$C$1,1,0,COUNTA('Employee Database'!$C:$C)-1,1)

Add Conditional Formatting

On the Data sheet, highlight A2:C whatever (ex: A2:C20000 ), then go to Home » Styles » Conditional Formatting and use the following formula:

=ISNA(MATCH($A2,Emails,0))

Select the color scheme you want and click OK . Here's how it looks on my computer with some sample data:

There are a few minor constraints:

• You cannot leave column A blank on the Data sheet any more.
• You cannot have blank rows on the Employee Database sheet in between rows of data. This is due to the way the dynamic range works.

Benefits

The benefits of this approach are, IMO, huge.

• You can add or remove rows from the Employee Database sheet, and the highlighting will automatically adjust. Ex: if I add d@gmail.com and remove c@nbc.com, the formatting on the Data sheet updates immediately.

• You don't have to alter your existing worksheet structure (other than filling in the missing data and adding a range name). No need for additional worksheets.
• Your workbook can stay VBA-free (if it didn't have any already).