Emacs 正则表达式计数出现

Question

I'm looking for the fastest routine (not interactively) to get the number of matches of a regexp in a string.

Something like

(count-occurrences "a" "alabama")
=> 4

Answer 1

count-matches does it interactively. Maybe a good place to start looking.

Answer 2

how-many (aliased count-matches ) does this, but works on buffers.

Here is one that works on strings:

(defun how-many-str (regexp str)
  (loop with start = 0
        for count from 0
        while (string-match regexp str start)
        do (setq start (match-end 0))
        finally return count))

Answer 3

Here is a more functional answer using recursion and an accumulator. As an added benefit, it does not use cl :

(defun count-occurences (regex string)
  (recursive-count regex string 0))

(defun recursive-count (regex string start)
  (if (string-match regex string start)
      (+ 1 (recursive-count regex string (match-end 0)))
    0))

Answer 4

在包s 中，有函数s-count-matches 。

Answer 5

If you don't have any problems creating a copy of the variable, you can try

(- (length (split-string "Hello World" "o")) 1)
(- (length (split-string "aaabaaa" "a")) 1)
(- (length (split-string "This
string
has three
newlines" "
")) 1)

2
6
3

If you don't have any problem loading the cl-lib package, then you can try

(require 'cl-lib)

(cl-count ?o "Hello World")
(cl-count ?a "aaabaaa")
(cl-count ?
 "This
string
has three
newlines")

2
6
3

Answer 6

Here is a emacs-lisp function that does not use a stack

(defun count-occurences-in-string (pattern string)
  "Count occurences of PATTERN in STRING."
  (let ((occurences 0)
        (start 0)
        (length (length string)))
    (while (and
            (< start length)
            (string-match pattern string start))
      (setq occurences (1+ occurences))
      (setq start (match-end 0)))
    occurences))

Answer 7

I would probably do this:

(defun count-occurrences (regexp string)
  "Return the number of occurrences of REGEXP in STRING."
  (let ((count 0))
    (with-temp-buffer
      (save-excursion (insert string))
      (while (re-search-forward regexp nil t)
        (cl-incf count)))
    count))