Perl：贪婪的自然拒绝工作

Question

I am trying to replace a string with another string, but the greedy nature doesn't seem to be working for me. Below is my code where "PERFORM GET-APLCY" is identified and replaced properly, but string "PERFORM GET-APLCY-SOI-CVG-WVR" and many other such strings are being replaced by the the replacement string for "PERFORM GET-APLCY".

s/PERFORM $func[$i]\.*/#  PERFORM $func[$i]\.\n $hash{$func[$i]}/g;

where the full stop is optional during string match and replacement. I have also tried giving the pattern to be matched as $func[$i]\\b Please help me understand what the issue could be.

Thanks in advance, Faez

Answer 1

Why GET-APLCY- should not match GET-APLCY. , if the dot is optional?

Easy solution: sort your array by length in descending order.

@func = sort { length $b <=> length $a } @func

Testing script:

#!/usr/bin/perl
use warnings;
use strict;
use feature 'say';

my %hash = ('GET-APLCY'              => 'REP1',
            'GET-APLCY-SOI-CVG-WVR'  => 'REP2',
            'GET-APLCY-SOI-MNG-CVRW' => 'REP3',
           );

my @func = sort { length $b <=> length $a } keys %hash;

while (<DATA>) {
    chomp;
    print;
    print "\t -> \t";
    for my $i (0 .. $#func) {
        s/$func[$i]/$hash{$func[$i]}/;
    }
    say;
}

__DATA__
GET-APLCY param
GET-APLCY- param
GET-APLCY. param
GET-APLCY-SOI. param
GET-APLCY-SOI-CVG-WVR param
GET-APLCY-SOI-MNG-CVRW param

Answer 2

You appear to be looping over function names, and calling s/// for each one. An alternative is to use the e option, and do them all in one go (without a loop):

my %hash = (
  'GET-APLCY'             => 'replacement 1',
  'GET-APLCY-SOI-CVG-WVR' => 'replacement 2',
);

s{ 
  PERFORM \s+   # 'PERFORM' keyword 
  ([A-Z-]+)     # the original function name
  \.?           # an optional period
}{
  "#  PERFORM $1.\n" . $hash{$1};
}xmsge;

The e causes the replacement part to be evaluated as an expression. Basically, the first part finds all PERFORM calls (I'm assuming that the function names are all upper case with '-' between them – adjust otherwise). The second part replaces that line with the text you want to appear.

I've also used the x , m , and s options, which is what allows the comments in the regular expression, among other things. You can find more about these under perldoc perlop .

A plain version of the s -line should be:

s/PERFORM ([A-Z-]+)\.?/"#  PERFORM $1.\n" . $hash{$1}/eg;

Answer 3

I guess that $func[$i] contains "GET-APLCY". If so, this is because the star only applies to the dot, an actual dot, not "any character". Try

s/PERFORM $func[$i].*/#  PERFORM $func[$i]\.\n $hash{$func[$i]}/g;

Answer 4

I'm pretty sure you trying to do some kind of loop for $i. And in that case most likely GET-APLCY is located in @func array before GET-APLCY-SOI-CVG-WVR. So I recommend to reverse sort @func before entering loop.